force maximum simplification of radicals in a traditional way-How to do it?

Question

this should be simple but I can't get mathematica to simplify a radical or a set of radicals and express them in the traditional way for example by simplifying this

FullSimplify[(3 a (18 a^4)^(1/4))^3, a > 0]// TraditionalForm (edited)

results in this $$81\ 2^{3/4} \sqrt{3} a^6$$ or this $$27\ 18^{3/4} a^6$$

but not this,

$$81 \sqrt[4]{72} a^6$$

which is the final and most compact

There is some way I can simplify even more and from the results in a traditional way, this is just a small example.

Answer 1

FullSimplify[(3 a (18 a^4)^(1/4))^3, a > 0] /. 
    x_^Rational[y_, z_]*Sqrt[a_] :> (Defer@*Surd)[x^y*a^(z/2), z]

$81 \sqrt[4]{72} a^6$

---

since $a^{b/c}$ partly $=\sqrt[c]{a^b}$ , so we want to match a,b,c.

But

2^(3/4) /. a_^(b_/c_) :> {a, b, c}

doesn't work.

Because

b/c // AtomQ  (*False*)
3/4 // AtomQ  (*True*)

So mma see 3/4 as a whole.

2^(3/4) // FullForm (*Power[2,Rational[3,4]]*)

Which means we can use

2^(3/4) /. a_^Rational[b_, c_] :> {a, b, c} (*{2,3,4}*)

After that, use Surd and Defer to control the calculation.

Answer 2

It is a matter of taste what is simpler. But you can always overwrite MMA decisions by e.g.:

 FullSimplify[(3 a (18 a^4)^(1/4))^3, a > 0] /. 
  2^(3/4) Sqrt[3] -> HoldForm[72^(1/4)] // TraditionalForm

Answer 3

This combines fractional powers of integers to arrive at the form $n^{1/d}$ of a root of an integer. It assumes that the fractional powers came from Power automatically expanding a reduced power.

Simplify[(3 a (18 a^4)^(1/4))^3, a > 0] //.
  Power[b1 : (_Integer | _Hold), r1_Rational]*
    Power[b2 : (_Integer | _Hold), r2_Rational] :>
   With[{d = LCM[Denominator[r1], Denominator[r2]]},
    Power[
     ReleaseHold[b1]^(d*r1) ReleaseHold[b2]^(d*r2) //
       Evaluate // Hold,
     1/d]
    ] /. Hold -> Defer

Answer 4

I wrote DisplayPowersTogether to do this sort of thing.

DisplayPowersTogether=ResourceFunction["DisplayPowersTogether"];
DisplayPowersTogether@FullSimplify[(3 a (18 a^4)^(1/4))^3,a>0]

$81 \sqrt[4]{72} a^6$

For ResouceFunctions that you use often, download the source notebook, so you don't have to wait for ResourceFuntion every time. Instead, you can put the code in your init.m file.