2
$\begingroup$

I've been trying to solve it with Mathematica Order of DSolve but I'm not getting Anywhere! so if anyone got an idea i would be glad to tell me how to get answer

p.s:I just want solution and Numerical solution with NDSolve won't help me Tnx. [![enter image description here] 1]1 enter image description here

$\endgroup$
  • 3
    $\begingroup$ 1. Shows us the code you used as text, not as an image, including the specific call to DSolve you tried. 2. There may not be an analytical solution. Do you have reason to believe that one should exist for this system? $\endgroup$ – MarcoB Sep 6 at 15:24
2
$\begingroup$

The three PDEs

eq1 = D[f[xm, xp], xm, xp] - 2 f[xm, xp]/(xm - xp)^2 == 0;
eq2 = D[f[xm, xp], xp, xp] - 2 D[f[xm, xp], xp]/(xm - xp) == 0;
eq3 = D[f[xm, xp], xm, xm] + 2 D[f[xm, xp], xm]/(xm - xp) == 0;

clearly are satisfied by f[xm, xp] = 0. In fact, this is the only solution. As noted in the Question,DSolve cannot solve the three PDEs together. Indeed, it cannot solve even eq1 alone. But it can solve the second and third PDEs (actually ODEs) individually.

s2 = Together@DSolveValue[eq2, f[xm, xp], {xm, xp}] /. {C[1] -> c1, C[2] -> c2}
s3 = Together@DSolveValue[eq3, f[xm, xp], {xm, xp}] /. {C[1] -> c3, C[2] -> c4}
(* (c1[xm] + xm c2[xm] - xp c2[xm])/(xm - xp) *)
(* (-c3[xp] + xm c4[xp] - xp c4[xp])/(xm - xp) *)

The two solutions must be equal, i.e., s0 == 0, where

s0 = Simplify[s2 - s3]
(* (c1[xm] + (xm - xp) c2[xm] + c3[xp] - xm c4[xp] + xp c4[xp])/(xm - xp) *)

From this, the four unknown functions can be determined up to constants.

D[Numerator@s0, xm, xp] == 0
r2 = Flatten@{DSolve[Derivative[1][c2][xm] == c, c2[xm], xm] /. C[1] -> c2c, 
              DSolve[Derivative[1][c4][xp] == -c, c4[xp], xp] /. C[1] -> c4c}
(* -c2'[xm] - c4'[xp] == 0 *)
(* {c2[xm] -> c2c + c xm, c4[xp] -> c4c - c xp} *)

where `c == -c2'[xm] == -c4'[xp]. Then,

Numerator[s0 /. r2] == 0;
sc1 = Flatten@DSolve[D[%, xm], c1[xm], xm] /. C[1] -> c1c
sc2 = Flatten@DSolve[D[%%, xp], c3[xp], xp] /. C[1] -> c3c
(* {c1[xm] -> c1c - c2c xm + c4c xm - c xm^2} *)
(* {c3[xp] -> c3c + c2c xp - c4c xp + c xp^2} *)

Simplify@Numerator[s0 /. r2 /. sc1 /. sc2] == 0
(* c1c + c3c == 0 *)

The solution, then, is

s = Simplify[s3 /. r2 /. sc1 /. sc2 /. c1c -> -c3c]
(* -((c3c - c4c xm + c2c xp + c xm xp)/(xm - xp)) *)

Simplify[eq1[[1]] /. f -> Function[{xm, xp}, s]]
Flatten@CoefficientList[Numerator[%], {xm, xp}]
Flatten@Solve[Thread[% == 0], {c, c2c, c3c, c4c}]
(* (2 (c3c - c4c xm + (c2c + c xm) xp))/(xm - xp)^3 *)
(* {2 c3c, 2 c2c, -2 c4c, 2 c} *)
(* {c -> 0, c2c -> 0, c3c -> 0, c4c -> 0} *)

All the constants are zero.

Addendum: Simpler solution

A much simpler derivation of the same result can be obtained by solving eq2 and inserting the solution into eq1.

Flatten@DSolve[eq2, f, {xm, xp}];
Collect[eq1[[1]] /. %, xm - xp, Simplify]
(* -((4 C[1][xm])/(xm - xp)^3) + (-2 C[2][xm] + C[1]'[xm])/(xm - xp)^2 *)

Because xm and xm - xp are independent quantities, the coefficient of each power of xm - xp must vanish. In other words, C[1][xm] = C[2][xm] = 0.

| improve this answer | |
$\endgroup$
  • $\begingroup$ thanks for your solution yes this was exactly what i was looking for although i didn't needed determining of constants cause it will be determined through the problem i've been working on but thanks anyway! $\endgroup$ – fysh96 Sep 6 at 21:50

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.