1
$\begingroup$

I want to make a presentation of the maps of the standard complex functions, as well as some mobius transformations and special complex functions.

I want to present it exactly like it is done in the answer from Michael E2 to this question: How can I improve my code for visualizing a complex map?

With one difference however. I want to show the effect of a complex function on the basic grid containing of squares 1-by-1, instead of the grid of 'polygons in circles' in that answer. I am lost in how to do that.

How should I do this? ( How can I apply a complex function to the basic grid? )

$\endgroup$
5
  • 1
    $\begingroup$ See this demo demonstrations.wolfram.com/ConformalMaps $\endgroup$
    – yarchik
    Aug 28 '20 at 13:56
  • $\begingroup$ This is another relevant demo demonstrations.wolfram.com/ConformalMapOfExponential $\endgroup$
    – yarchik
    Aug 28 '20 at 13:57
  • $\begingroup$ Thank you very much for these links, I always check Wolfram Demos but didn't find them. - I hope that from studying the source code of these demos I can move on. The point is that it is not just the Conformal Mappings I want to demonstrate but basically all complex functions. $\endgroup$ Aug 28 '20 at 14:10
  • 2
    $\begingroup$ Block[{z = x + I y}, ParametricPlot[ReIm[(z + 1)/(z - 1)], {x, -Pi, Pi}, {y, -2, 2}, Mesh -> 9, Axes -> False]] $\endgroup$
    – cvgmt
    Aug 28 '20 at 14:12
  • $\begingroup$ Thanks. Is it that simple? - You can put that in an answer. $\endgroup$ Aug 28 '20 at 14:20
2
$\begingroup$
 Block[{z = x + I y}, 
  ParametricPlot[ReIm[(z + 1)/(z - 1)], {x, -6, 6}, {y, -6, 6}, 
   MeshFunctions -> Automatic, Mesh -> {Range[-4, 4], Range[-4, 4]}, 
   Axes -> False, PlotStyle -> None, Axes -> False, MeshStyle -> Blue,
    BoundaryStyle -> Directive[Dotted, Red, Thick], PlotPoints -> 50]];
Block[{z = x + I y}, 
  ParametricPlot[
     ReIm[(z + 1)/(z - 1)], {x, #1, #1 + 1}, {y, #2, #2 + 1}, 
     MeshFunctions -> Automatic, 
     Mesh -> {Range[#1, #1 + 1], Range[#2, #2 + 1]}, 
     MeshShading -> {{None, None}, {None, Yellow}}, Axes -> False, 
     PlotStyle -> None, Axes -> False, MeshStyle -> Blue, 
     PlotPoints -> 50] & @@@ {{2, 2}, {3, 2}, {4, 2}, {3, 3}, {3, 1}}];
Show[%, %%, PlotRange -> {{-1, 3}, {-2, 2}}]

enter image description here

Block[{z = x + I y}, 
  RegionPlot[
   RegionUnion[
    ParametricRegion[
       ReIm[z], {{x, #1, #1 + 1}, {y, #2, #2 + 1}}] & @@@ {{2, 2}, {3,
        2}, {4, 2}, {3, 3}, {3, 1}}], BoundaryStyle -> LightRed, 
   PlotStyle -> LightGreen, PlotRange -> All]];
Block[{z = x + I y}, 
  RegionPlot[
   RegionUnion[
    ParametricRegion[
       ReIm[(z + 1)/(z - 1)], {{x, #1, #1 + 1}, {y, #2, #2 + 
          1}}] & @@@ {{2, 2}, {3, 2}, {4, 2}, {3, 3}, {3, 1}}], 
   BoundaryStyle -> Red, PlotStyle -> Yellow]];
GraphicsRow[{%%, %}]

enter image description here

a = Block[{z = x + I y},
   Show[ParametricPlot[ReIm[z], {x, -6, 6}, {y, -6, 6}, 
     MeshFunctions -> Automatic, Mesh -> {Range[-5, 5], Range[-5, 5]},
      Axes -> False, PlotStyle -> None, Axes -> False, 
     MeshStyle -> Blue, 
     BoundaryStyle -> Directive[Dotted, Red, Thick], PlotPoints -> 50],
    RegionPlot[
     RegionUnion[
      ParametricRegion[
         ReIm[z], {{x, #1, #1 + 1}, {y, #2, #2 + 1}}] & @@@ {{2, 
         2}, {3, 2}, {4, 2}, {3, 3}, {3, 1}}], BoundaryStyle -> Red, 
     PlotStyle -> Yellow], PlotRange -> {{-6, 6}, {-6, 6}}]];
b = Block[{z = x + I y},
   Show[ParametricPlot[ReIm[(z + 1)/(z - 1)], {x, -6, 6}, {y, -6, 6}, 
     MeshFunctions -> Automatic, Mesh -> {Range[-5, 5], Range[-5, 5]},
      Axes -> False, PlotStyle -> None, Axes -> False, 
     MeshStyle -> Blue, 
     BoundaryStyle -> Directive[Dotted, Red, Thick], PlotPoints -> 50],
    RegionPlot[
     RegionUnion[
      ParametricRegion[
         ReIm[(z + 1)/(
          z - 1)], {{x, #1, #1 + 1}, {y, #2, #2 + 1}}] & @@@ {{2, 
         2}, {3, 2}, {4, 2}, {3, 3}, {3, 1}}], BoundaryStyle -> Red, 
     PlotStyle -> Yellow], PlotRange -> {{-2, 3}, {-2, 2}}]];
GraphicsRow[{a, b}]

enter image description here

$\endgroup$
1

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.