4
$\begingroup$

The following definite integral describing the density of the normal part of a superfluid equals to $$ \int_0^\infty dx\, x^4\, \frac{e^{x^2+a}}{\left(e^{x^2+a}-1\right)^2} = \frac{3\sqrt{\pi}}{8}Li_{3/2}(e^{-a})\quad , \qquad a>0\, . $$ However, if one types the above expression into Mathematica

Integrate[ x^4 Exp[x^2+a]/(Exp[x^2 + a] - 1)^2, {x, 0, ∞}, Assumptions -> a > 0] 

then it simply returns the input.

Why is that and how can one solve these kind of problems?

I've been thinking for quite a while now, that the above integral does not have a closed form solution because Mathematica couldn't solve it.

$\endgroup$
  • 1
    $\begingroup$ The RHS of the formula you asked for is not a closed-form expression. In fact,the integral under consideration is expressed in the terms of another integral..Hope you understand Mathematica is not a table of integrals. $\endgroup$ – user64494 Aug 27 at 10:01
  • $\begingroup$ True, thank you for making that point. However, there are expressions where Mathematica does give special functions as results to integrals similar as above. Is there a way, to make Mathematica express these kind of integrals in terms of special functions? $\endgroup$ – mr. curious Aug 27 at 10:04
  • 1
    $\begingroup$ The question arises: what for? Isn't it art for art's sake? $\endgroup$ – user64494 Aug 27 at 10:06
  • 3
    $\begingroup$ Well, it is the accepted way of writing those integrals in the literature and if one sees special functions one immediately knows that the integral at hand corresponds to some special functions. Additionally, one can apply all the current knowledge that we have about the properties of the special functions to the integral, once we know that this integral corresponds to a special function. $\endgroup$ – mr. curious Aug 27 at 10:13
  • $\begingroup$ Did you look in Gradstein&Ruezhik to this end (They give references to the formulas.)? Good luck! $\endgroup$ – user64494 Aug 27 at 10:17
10
$\begingroup$

We can see that the integrand is a derivative with respect to $a$ (the integral is absolutely convergent and continuously differentiable so integration and differentiation is commutative) of a bit simpler function which can be integrated, i.e we can see that $$\frac{d}{da}\; \frac{x^k}{\exp(x^2+a)-1}=-\frac{x^k \exp(x^2+a)}{(\exp(x^2+a)-1)^2}$$ and now we can evaluate even a more general integral of the form $$ \int_0^\infty dx\, \frac{x^k e^{x^2+a}}{\left(e^{x^2+a}-1\right)^2} $$

int[k_,a_] = Integrate[ -x^k/(Exp[x^2 + a] - 1), {x, 0, Infinity}, 
                        Assumptions -> a > 0 && k > 0]
-(Gamma[(1 + k)/2] PolyLog[(1 + k)/2, E^(-a)])/2

i.e. the more general integral takes form:

D[ int[k,a], a]
 (Gamma[(1 + k)/2] PolyLog[-1 + (1 + k)/2, E^(-a)])/2

so it is in case of the original question

 % /. k -> 4 // TraditionalForm

enter image description here

In any case one can also compare the integral with its numerical counterpart, e.g.

nint[k_, a_]:= NIntegrate[ x^k Exp[x^2 + a]/(Exp[x^2 + a] - 1)^2,{x, 0, Infinity}]

 Plot[{3/8 Sqrt[Pi] PolyLog[3/2, Exp[-a]], nint[4,a]}, {a, 0, 3},
   PlotStyle -> {Dashed, Dashing[{0.02, 0.05}]}]

enter image description here

| improve this answer | |
$\endgroup$
  • 1
    $\begingroup$ @user64494 I fixed that before you pointed it out, as can be seen from the substatial part of the edit and so you should upvote it rather than downvote. $\endgroup$ – Artes Aug 27 at 11:58
  • 3
    $\begingroup$ @Artes Very tricky solution ! Don't worry about several comments... $\endgroup$ – Ulrich Neumann Aug 27 at 12:23
  • 2
    $\begingroup$ It is clever, yes. $\endgroup$ – Daniel Lichtblau Aug 27 at 14:32
  • 2
    $\begingroup$ @Artes Ok! I gave this answer yesterday on Physics using Mathematica and now I see this answer on Mathematica with using physics. :) $\endgroup$ – Alex Trounev Aug 27 at 15:00
  • 4
    $\begingroup$ @user64494 What are you talking about? $\endgroup$ – Alex Trounev Aug 27 at 16:42

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.