How to find some matrices that satisfy the constraints

Question

I know that the three eigenvalues of the real third order matrix A are -1, 1, 1, and the eigenvector corresponding to eigenvalue -1 is $(0,1,1)^T$. I want to find a matrix A that meets the requirements.

A = Array[x, {3, 3}];
FindInstance[(Eigenvalues[A] == {-1, 1, 
     1}) && (A.{{0, 1, 1}}\[Transpose] == -1*{{0, 1, 1}}\[Transpose]) , Flatten[A], Reals]

But the above code returns an empty set. What can I do to find some matrices that meet the constraints?

Answer 1

I think this does what you want

First we try to narrow down the search space a little

A = {{a, b, c}, {d, e, f}, {g, h, i}};
A.{0, 1, 1} == -1 * {0, 1, 1}

returns

{b + c, e + f, h + i} == {0, -1, -1}

then

sol = FindInstance[Eigenvalues[{{a, b, -b}, {d, e, -1 - e}, {g, h, -1 - h}}] ==
                               {-1, 1, 1}, {a, b, d, e, g, h}, Integers]

returns

{{a -> 0, b -> -1, d -> 0, e -> 0, g -> -1, h -> -2}}

Note: Changing that Integers to Reals and adding the number of desired solutions will let FindInstance give you more matrices if that is what you need.

and

mat = {{a, b, -b}, {d, e, -1 - e}, {g, h, -1 - h}} /. sol

returns

{{{0, -1, 1}, {0, 0, -1}, {-1, -2, 1}}}

and

Eigensystem[mat]

returns

{{-1, 1, 1}, {{0, 1, 1}, {2, -1, 1}, {0, 0, 0}}}

which seems to satisfy your conditions.

Please check all this very carefully.