How to calculate totals in datasets with GroupBy applied to Values

Question

I have the following Dataset:

ExData = Import["Example.xlsx", {"Dataset", 1}, "HeaderLines" -> 1];

I would like to get the total of Stage1+Stage2 and Stage3+Stage4+Stage5 grouping by Supplier but I am not able to extend the instruction:

ExData[GroupBy[#[["Supplier"]] &], GroupBy[#[["Stage"]] &], Total, #[["Amount"]] &]

which gives:

to get GroupBy work in combination with values. Is there a clever way to use GroupBy for this purpose? Thanks !

Answer 1

Using a variation of data from Alan's answer:

SeedRandom[1]
data = Dataset@
  Table[Association["Sector" -> RandomChoice[{"Energy", "Env"}], 
    "Supplier" -> StringTemplate["N``"]@RandomInteger[5], 
    "Stage" -> "Stage" <> ToString[RandomInteger[{1, 5}]], 
    "Amount" -> 1000*RandomInteger[200]], 100]

data[GroupBy["Supplier"], 
 GroupBy[Switch[#Stage, "Stage1" | "Stage2", "stages12", _, "stages345"] &], 
 Total, "Amount"]

Alternatively, use KeySort to reorganize the output:

data[GroupBy["Supplier"] /* KeySort, 
 GroupBy[Switch[#Stage, "Stage1" | "Stage2", "stages12", _, "stages345"] &] /* KeySort, 
 Total, "Amount"]

Answer 2

Edited in response to change in question added in a comment:

data = Dataset@Table[Association[
     "Sector" -> RandomChoice[{"Energy", "Env"}],
     "Supplier" -> StringTemplate["N``"]@RandomInteger[5],
     "Stage" -> StringTemplate["Stage``"]@RandomInteger[5],
     "Amount" -> 1000*RandomInteger[200]
     ], 100];
grp = GroupBy["Supplier"]
data[grp, Total, "Amount"]

Your comment says you only want to total over a Stage1 and Stage 2, so select for these.

sel = Select["Stage1" == #Stage || "Stage2" == #Stage &]
data[sel][grp, Total, "Amount"]