8
$\begingroup$

I am playing around with Simplify amd assumptions. I noticed that:

Simplify[x > (a + b)/e, x < (a + b)/e]
False

But if I add more variables to the numerator, Simplify is not able to get False

Simplify[x > (a + b + c)/e, x < (a + b + c)/e]
x > (a + b + c)/e

Why is there such a difference and how can I avoid the latter situation?

$\endgroup$
3
  • 4
    $\begingroup$ Note that Reduce[{x > (a + b + c)/e, x < (a + b + c)/e}] does return False as expected, so that might be a work-around. $\endgroup$ – Michael Seifert Jul 29 '20 at 14:38
  • $\begingroup$ Simplify[x > (a + b + c)/e && x < (a + b + c)/e] $\endgroup$ – Alan Jul 29 '20 at 14:49
  • $\begingroup$ Related: mathematica.stackexchange.com/questions/118492/… $\endgroup$ – Michael E2 Jul 29 '20 at 16:16
6
$\begingroup$

You can set a higher value for the system sub-option "AssumptionsMaxNonlinearVariables" than its default value 4:

"AssumptionsMaxNonlinearVariables" /. 
    "SimplificationOptions" /. 
       SystemOptions["SimplificationOptions"]
 4
Simplify[x > (a + b + c)/e, x < (a + b + c)/e]
 x > (a + b + c)/e
Simplify[x > (a + b + c + z)/e, x < (a + b + c + z)/e]
 x > (a + b + c + z)/e
ClearSystemCache[]
SetSystemOptions["SimplificationOptions" -> {"AssumptionsMaxNonlinearVariables" -> 7}];

Simplify[x > (a + b + c)/e, x < (a + b + c)/e]
False
Simplify[x > (a + b + c + z)/e, x < (a + b + c + z)/e]
False
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.