Finding derivatives occurring in an expression

Question

I would like to find the derivatives of a function U[x,y,t] occurring in an expression X. I use

DeleteDuplicates[Cases[X, Derivative[__][U][__], Infinity]].

An output would be something like this:

{Derivative[1, 0, 0][U][x, y, t], 
 Derivative[0, 1, 0][U][x, y, t], 
 Derivative[0, 2, 0][U][x, y, t], 
 Derivative[1, 1, 0][U][x, y, t], 
 Derivative[2, 0, 0][U][x, y, t], 
 Derivative[0, 1, 1][U][x, y, t], 
 Derivative[1, 0, 1][U][x, y, t], 
 Derivative[0, 0, 1][U][x, y, t],
 Derivative[1, 1, 1][U][x, y, t], 
 Derivative[0, 2, 1][U][x, y, t]}

However, if I want to find a particular nth derivative of U, say 3rd derivative, in the expression to get the following:

 {Derivative[1, 1, 1][U][x, y, t], 
 Derivative[0, 2, 1][U][x, y, t]}

how would I achieve that?

Answer 1

You need to specialise your pattern:

DeleteDuplicates[Cases[X, Derivative[i__][U][__]/;Plus[i]==3, -1]]

Answer 2

X can be any PDE, even a system of PDEs, not necessarily linear.

getPatterns[expr_, pat_] := 
  Last@Reap[expr /. a : pat :> Sow[a], _, Sequence @@ #2 &];

pde = Derivative[1, 1, 1][U][x, y, t] + 
   Derivative[0, 2, 1][U][x, y, t]^3 + 
   Derivative[0, 1, 1][U][x, y, t] + Sin[x] + F'[x] + 
   Derivative[3, 0, 0][U][x, y, t] + Derivative[2, 1, 0][U][x, y, t];

getPatterns[pde, 
 Derivative[x0_, y0_, t0_][U][_, _, _] /; x0 + y0 + t0 == 3]

Function getPatterns is thanks to Carl Woll.