Creating a list from other lists and varying the number of elements that get added

Question

Suppose I have

 listA = {M, F}

and

ListB = {a,b,c}

I want to make a new

listC = {{Ma, Mb, Mb, Mb, Mc, Mc}, {Fa, Fb, Fb, Fb, Fc, Fc}} 

Where I tell Mathematica how many copies of a particular element to make in listC.

Outer[] seems like a good start but it returns the combined elements as a two item list. For example I get {M, a} instead of M a.

Answer 1

I just noticed your comment under the question that you actually do want new symbols. I shall give an example of that and also multiplication.

It is more efficient to perform the operation (multiplication, etc.) and then make the copies, rather than making copies and performing the operation anew on each.

f[A_, B_, R_, f_: Times] := Inner[ConstantArray, Outer[f, A, B], R, Join]

f[{M, F}, {a, b, c}, {1, 3, 2}

{{a M, b M, b M, b M, c M, c M}, {a F, b F, b F, b F, c F, c F}}

Symbols:

makeSym = Symbol @ ToString @ Row @ {##} &;

f[{M, F}, {a, b, c}, {1, 3, 2}, makeSym]

{{Ma, Mb, Mb, Mb, Mc, Mc}, {Fa, Fb, Fb, Fb, Fc, Fc}}

With argument checking for practical use:

f[A_List, B_List, R : {__Integer}, f_: Times] /;
 Min[R] >= 0 && Length@B == Length@R :=
  Inner[ConstantArray, Outer[f, A, B], R, Join]

Answer 2

Assuming Ma is the product M * a, you could state the number of copies:

copies = {1, 3, 2};

Then make these copies:

listD = Flatten[Inner[Table[#1, {#2}] &, listB, copies, List]]

{a, b, b, b, c, c}

And finally combine them with the first list:

Outer[Times, listA, listD]

{{a M, b M, b M, b M, c M, c M}, {a F, b F, b F, b F, c F, c F}}

Update

If you really want a new symbol Ma, you could perhaps do this with strings.

listA = {"M", "F"};
listB = {"a", "b", "c"};
copies = {1, 3, 2};
listD = Flatten[Inner[Table[#1, {#2}] &, listB, copies, List]];
Outer[ToExpression[#1 <> #2] &, listA, listD]

{{Ma, Mb, Mb, Mb, Mc, Mc}, {Fa, Fb, Fb, Fb, Fc, Fc}}

Answer 3

Another variant of BoLe's answer using Outer:

lA = {"M", "F"};
lB = {"a", "b", "c"};
lC = {1, 3, 2};

Outer[ToExpression[#1 <> #2] &, lA, Flatten[ConstantArray @@@ Transpose@{lB, lC}]] 
(*using AbsoluteTiming*)

{0.0001178, {{Ma, Mb, Mb, Mb, Mc, Mc}, {Fa, Fb, Fb, Fb, Fc, Fc}}}

Outer[ToExpression[#1 <> #2] &, lA, Flatten[Inner[Table[#1, {#2}] &, lB, lC, List]]]
(*using AbsoluteTiming*)

{0.0002433, {{Ma, Mb, Mb, Mb, Mc, Mc}, {Fa, Fb, Fb, Fb, Fc, Fc}}}

Answer 4

mf = {M, F};
abc = {a, b, c};

Map[
  Symbol @* StringJoin,
  Map[
   ToString,
   Thread[{#, abc}] & /@ mf,
   {3}],
  {2}][[All, {1, 2, 2, 2, 3, 3}]]

{{Ma, Mb, Mb, Mb, Mc, Mc}, {Fa, Fb, Fb, Fb, Fc, Fc}}