3
$\begingroup$

I'm trying to change radial range in PolarPlot so that oscillations could be more visible:

PolarPlot[{1, 1 + 1/100 Sin[10 t]}, {t, 0, 2 Pi}]

In order to do so, the range should not start from zero, but from a certain value. Can anyone help with this one?

$\endgroup$
2
  • 1
    $\begingroup$ Given that cutting a disk out of the center changes nothing, the only way forward is to scale the radial distance in a polar plot by some compressive nonlinearity, for instance $r \to \sqrt{r}$. $\endgroup$ – David G. Stork Jun 7 '20 at 20:43
  • $\begingroup$ I found a naive way using Rescale : MinR = 0.97; MaxR = 1.03; SclFunc[x_] := Rescale[x, {MinR, MaxR}]; PolarPlot[ {SclFunc@1, SclFunc@(1 + 1/100 Sin[10 t])}, {t, 0, 2 \[Pi]} , PlotRange -> 1.2 , PolarAxesOrigin -> {0, 1} , PolarAxes -> True , PolarTicks -> {"Degrees", {{0, MinR}, {0.5, (MinR + MaxR)/2}, {1, MaxR}}} ] $\endgroup$ – Adam Jun 8 '20 at 10:39
3
$\begingroup$
Clear["Global`*"]

If you plot the Log, then the baseline (r == 1) is zero, above the baseline is a positive radius, and below the baseline is a negative radius.

pplt = Legended[
 PolarPlot[Log[1 + 1/100 Sin[10 t]], {t, 0, 2 Pi},
  PlotPoints -> 100, 
  ColorFunction -> Function[{x, y, t, r}, ColorData["Rainbow"][r]]],
 BarLegend[{"Rainbow", {Log[0.99], Log[1.01]}}]];

Animate[
 Show[pplt,
  Graphics[{Black, AbsolutePointSize[6],
    Point[Log[1 + 1/100 Sin[10 t]] {Cos[t], Sin[t]}]}]],
 {{t, 0, Style["θ", 14]}, 0, 2 Pi, Appearance -> "Labeled"},
 AnimationRate -> .0075]

enter image description here

$\endgroup$
0
$\begingroup$

I can't imagine a way of carving a circular hole out of the plot as you suggest, but perhaps you could concnetrate on one side of the function:

With[{center = 0.67, range = 0.2},
 PolarPlot[
  {1, 1 + 1/100 Sin[10 t]}, {t, 0, 2 Pi},
  AxesOrigin -> {center, center},
  PlotRange -> ConstantArray[{center - range, center + range}, 2]
 ]
]

portion of plot

$\endgroup$
2
  • $\begingroup$ Thank you for your answer. Actually I'm trying to plot some experimental data and a fitting to them to show symmetry of a system , so the whole 2 pi range would be very useful. Maybe there is way to combine few such sides in one plot? Or there is another way , not necessarily with PolarPlot but still carving the hole? $\endgroup$ – Adam Jun 7 '20 at 20:00
  • $\begingroup$ @Adam I am not sure that I can imagine how to meet your two requirements at the same time. They seem physically incompatible. $\endgroup$ – MarcoB Jun 7 '20 at 21:09

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.