How to draw a surface with four space curves as boundaries of the surface?
ParametricPlot3D[{{u, 0, u^2}, {0, v, v^2}, {u, 1, u^2 + 1}, {1, v,1 + v^2}}, {u, 0, 1}, {v, 0, 1}]
From this one:
to this one:
Your answer is appreciated.
$\begingroup$
$\endgroup$
2
-
1$\begingroup$ These things are called 'Coons patches' - see here en.wikipedia.org/wiki/Coons_patch $\endgroup$– flintyJun 1, 2020 at 11:48
-
$\begingroup$ Sometimes, this is also referred to as "transfinite interpolation". $\endgroup$– J. M.'s lack of A.I. ♦Jun 1, 2020 at 12:15
Add a comment
|
1 Answer
$\begingroup$
$\endgroup$
1
As in my comment above, these are called 'Coons patches' https://en.wikipedia.org/wiki/Coons_patch
The following is simply adapted from the equations on that page:
c0[t_] := {t, 0, t^2}
d0[t_] := {0, t, t^2}
c1[t_] := {t, 1, 1 + t^2}
d1[t_] := {1, t, 1 + t^2}
lc[s_, t_] := (1 - t) c0[s] + t c1[s]
ld[s_, t_] := (1 - s) d0[t] + s d1[t]
b[s_, t_] :=
c0[0] (1 - s) (1 - t) + c0[1] s (1 - t) + c1[0] (1 - s) t + c1[1] s t
patch[s_, t_] := lc[s, t] + ld[s, t] - b[s, t]
Show[
ParametricPlot3D[#[t], {t, 0, 1}, PlotStyle -> {Thick, Red},
PlotRange -> All, BoxRatios -> 1] & /@ {c0, d0, c1, d1},
ParametricPlot3D[patch[s, t], {s, 0, 1}, {t, 0, 1}, PlotRange -> All,
BoxRatios -> 1]
]
-
$\begingroup$ I learned new things today. Thank you very much..^^ $\endgroup$– VTehJun 1, 2020 at 14:10