Two different Integration results for the same integrand in Mathematica

Question

I want to calculate $$ \int_0^\pi d\theta\sin\theta\, \left(\sqrt{1 \over 1-\left(1-(1-\gamma^2)^4\right)\cos^2\theta} - 1\right)^q $$.

For the simplest case of $q=1$ we have

q = 1;
A1 = Assuming[gamma ∈ Reals && 0 <= gamma < 1,
   Integrate[Sin[theta] (Sqrt[1/(1 - (1 - (1 - gamma^2)^4) Cos[theta]^2)] - 1) , theta]
   ];

B1 = Limit[A1, theta -> Pi, Direction -> "FromBelow"]  - Limit[A1, theta -> 0, Direction -> "FromAbove"];
B1 /. gamma -> 0.1

gives

0.0133732 + 0. I

Now, let's define $a = \left(1-(1-\gamma^2)^4\right)$, put it in the integrand and after integration put the value of $a$ back to the final expression in terms of $gamma$:

q = 1;
A2 = Assuming[a ∈ Reals && 0 <= a < 1,
   Integrate[Sin[theta] (Sqrt[1/(1 - a Cos[theta]^2)] - 1), theta]
   ] /. a-> (1 - (1 - gamma^2)^4);

B2 = Limit[A2, theta -> Pi, Direction -> "FromBelow"]  - Limit[A2, theta -> 0, Direction -> "FromAbove"]
B2 /. gamma -> 0.1

which gives

-31.6393 + 0. I

The two results are totally different symbolically and numerically, while the integrand is the same.

Answer 1

A1 and A2 have expressions containing logarithms meaning you run the risk of 'over-integrating' around the non-principal values of the logarithm - remember that $\log(z) = \log(|z|)+i (\arg(z)+2k\pi)$. If you add some additional assumptions theta >= 0 && theta \[Element] Reals to your A2 you get a matching answer with zero imaginary part:

A2 = Assuming[
    a \[Element] Reals && 0 <= a < 1 && theta >= 0 && 
     theta \[Element] Reals, 
    Integrate[Sin[theta] (Sqrt[1/(1 - a Cos[theta]^2)] - 1), 
     theta]] /. a -> (1 - (1 - gamma^2)^4);

B2 = Limit[A2, theta -> Pi, Direction -> "FromBelow"] - 
  Limit[A2, theta -> 0, Direction -> "FromAbove"]
B2 /. gamma -> 0.1
(*0.0133732*)