1
$\begingroup$

How can I find an asymptotic expansion for the inverse of the function $f[x]=x(1+x^{1/4})$ near $0$?


I tried substituting $z=x^{1/4}$ and using AsymptoticSolve to solve $y = z^4+z^5$ for $z[y]$ and then do $x[y] = z[y]^4$.

(z /. AsymptoticSolve[y == z^(4) + z^(5), {z, 0}, {y, 0, 1}][[1]])^(4)
(* output x[y] = (-y^(1/4) - Sqrt[y]/4 - (7 y^(3/4))/32 - y/4)^4 *)

If this is indeed the inverse, the difference $x[f[x]]-x$ should be small. When I do a series expansion for this difference, the leading term is $2 x^{5/4}$, but I suspect I am not doing things correctly since if I just try $x[y] = y(1-y^{1/4})$ as the inverse of $f$, I get a better leading term for $x[f[x]]-x$. I get something of the order $x^{3/2}$.

$\endgroup$
  • 2
    $\begingroup$ Have you already seen InverseSeries[]? $\endgroup$ – J. M.'s discontentment May 21 at 15:23
  • 1
    $\begingroup$ Thanks! Something like: InverseSeries[x + x^(4/3) + O[x]^2] ? $\endgroup$ – Cantor May 21 at 15:25
  • 3
    $\begingroup$ Any help?: z /. AsymptoticSolve[y == z^(4) + z^(5), {z, 0}, {y, 0, 1}][[1]] /. First@Solve[y == z^(4) + z^(5), y] // Series[#, {z, 0, 3}, Assumptions -> z > 0] & -- Note which branch was chosen, though. $\endgroup$ – Michael E2 May 21 at 15:31
  • 1
    $\begingroup$ The same as you I guess, but the branch is for the solution to y == x - x^(5/4). Since the 4th root has four branches, you have to pay attention to which was chosen by AsymptoticSolve. What you want is asol = AsymptoticSolve[y == z^(4) + z^(5), {z, 0}, {y, 0, 2}][[4]], the last branch returned instead of the first. $\endgroup$ – Michael E2 May 21 at 16:21
  • 1
    $\begingroup$ @user64494 You have to work over the complex numbers. Plot does not do that. $\endgroup$ – Michael E2 May 21 at 16:30
3
$\begingroup$

You question is somewhat unclearly formulated. If I correctly understand it, the following does the job.

Series[InverseFunction[# (1 + #^(1/4)) &][x], {x, 0, 2}]

$x-x^{5/4}+\frac{5 x^{3/2}}{4}-\frac{55 x^{7/4}}{32}+\frac{5 x^2}{2}+O\left(x^{9/4}\right)$

| improve this answer | |
$\endgroup$
  • $\begingroup$ Thanks, this answers my question. (what was unclear? perhaps I can edit the question) $\endgroup$ – Cantor May 21 at 15:48
  • $\begingroup$ @Cantor: You denote by $x$ both argument of $f(x)$ and argument of $f^{-1}(x)$. $\endgroup$ – user64494 May 21 at 15:57
  • 1
    $\begingroup$ This solution doesn't seem to work if I change 1/4 to 1/3. $\endgroup$ – Cantor May 21 at 18:14
2
$\begingroup$

As indicated in one of my comments, $y = z^4 + z^5$ has four branches in the neighborhood of $z=0$. AsymptoticSolve returns asymptotic series for all four. The last one is the one corresponding to $y = x+x^{5/4}$:

ClearAll[asol];
asol[n_] :=  (* n = order of series sought *)
  AsymptoticSolve[y == z^(4) + z^(5), {z, 0}, {y, 0, n}][[4]];

z^4 /. asol[2];
Series[%, {y, 0, 2}]
(*
y - y^(5/4) + (5 y^(3/2))/4 - (55 y^(7/4))/32 + (5 y^2)/2 -
 (7735 y^(9/4))/2048 + (3003 y^(5/2))/512 -
 (609615 y^(11/4))/65536 + O[y]^3
*)

The error that the OP was interested in ($x(f(x)) - x$):

z^4 /. asol[1] /. y -> (x + x^(5/4));
Series[% - x, {x, 0, 2}]
(*
-((663 x^2)/512) + (381 x^(9/4))/2048 - (1113 x^(5/2))/8192 +
 (3485 x^(11/4))/32768 + O[x]^3
*)

z^4 /. asol[2] /. y -> (x + x^(5/4));
Series[% - x, {x, 0, 3}]
(*
-((13042315 x^3)/2097152) - (34610147 x^(13/4))/8388608 +
 (46787 x^(7/2))/4194304 + (284843 x^(15/4))/16777216 + O[x]^4
*)
| improve this answer | |
$\endgroup$
  • $\begingroup$ As far as I understand it, the inverse function of $y=z^4+z^5 $ has five branches in the neighborhood of $y=0$. $\endgroup$ – user64494 May 21 at 16:53
  • $\begingroup$ In addition to my previous comment: the result ofTable[Root[-y + #1^4 + #1^5 &, k] /. y -> 0, {k, 1, 5}] is {-1, 0, 0, 0, 0}. $\endgroup$ – user64494 May 21 at 17:04
  • $\begingroup$ @user64494 OK, but how does that relate to what I said? $\endgroup$ – Michael E2 May 22 at 13:19

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.