5
$\begingroup$

In v. 11.1.0.0 Mathematica for Linux

Integrate[Sin[Cosh[t]], {t, 0, Infinity}]

returns

Integrate::idiv: Integral of Sin[Cosh[t]] does not converge on {0,[Infinity]}.

while the integral is clearly bounded.

NIntegrate[Sin[Cosh[t]], {t, 0, Infinity}]

seems to return a finite value.

Any idea of what is going on?

Improve this question
$\endgroup$
3
  • 2
    $\begingroup$ this is very highly oscillatory function. Are you sure it is NIntegrate which got it right, and not Integrate? Intergate can not integrate the indefinite integral also. So it must have done some checking before. $\endgroup$
    – Nasser
    May 18, 2020 at 22:23
  • 2
    $\begingroup$ @Nasser I think it converges, but I don't know whether it can be computed by Mathematica in terms of known functions. $\endgroup$
    – Michael E2
    May 18, 2020 at 23:07
  • 1
    $\begingroup$ In summary: please report this to Support. $\endgroup$
    – J. M.'s persistent exhaustion ♦
    May 19, 2020 at 11:17

2 Answers 2

Reset to default
13
$\begingroup$

I believe the integral in question converges conditionally and can be calculated after substituting $x = \cosh(t)$, giving (on the integration domain) $$t = \text{arccosh}(x), \;\; dt = \frac{dx}{\sqrt{x^2-1}}.$$

Integrate[Sin[x]/Sqrt[x^2 - 1], {x, 1, ∞}]

1/2 π BesselJ[0, 1]

N[%]

1.20197

We can numerically integrate over a large finite range, forcing each zero to be integrated over. This will ensure we're not skipping over any peaks or valleys.

NIntegrate[Sin[Cosh[t]], {t, ##}] & @@ Prepend[ArcCosh[π Range[10000]], 0]

1.20194

This extended syntax of NIntegrate is discussed here.

Improve this answer
$\endgroup$
1
11
$\begingroup$

Using the undocumented function Integrate`InverseIntegrate[]:

Integrate`InverseIntegrate[Sin[Cosh[t]], {t, 0, ∞}]
   1/2 π BesselJ[0, 1]

N[%, 20]
   1.2019697153172064991

which is consistent with Chip's reformulation:

NIntegrate[Sin[x]/Sqrt[x^2 - 1], {x, 1, ∞}, 
           Method -> "DoubleExponentialOscillatory", WorkingPrecision -> 20]
   1.2019697153164287403
Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.