Replace successively repeating sub-sequences by fewer of them

Question

Imagine I have a complicated sequence {....,a1,a2,a3,...,x1,x2,x1,x2,x1,x2,x1,x2,....,z1,z2,z3,...}

I want to replace the repeating pattern x1,x2,x1,x2,x1,x2,x1,x2 (which could be anything more than two - here it is four repetitions) by just x1,x2 or separately by x1,x2,x1,x2.

I tried SequenceReplace but was not successful.

SequenceReplace[{Repeated[PatternSequence[x1, x2], {2, Infinity}], 
e_} -> Union[{ x1, x2 }, e ]]@{x1, x2, x1, x2, x1, x2, x3, x4}

did not work..

Answer 1

ClearAll[seqReplace, removeRepeats]

seqReplace = SequenceReplace[{Repeated[p : PatternSequence[_, ___], {2, ∞}]} :> p];

removeRepeats = FixedPoint[seqReplace, #] &

Examples:

lst1 = {x1, x2, x1, x2, x1, x2, a, b, b, b, x3, x2, x1, x3, x2, x1, x1, x1, x1};

removeRepeats @ lst1

 {x1, x2, a, b, x3, x2, x1}

lst2 = {x1, x1, x2, x1, x2, x2, x2, x1, x2, a, b, b, x3, x2, x1, x3, x2, x1, x1, x1, x1};

removeRepeats @ lst2

 {x1, x2, a, b, x3, x2, x1}

Answer 2

Consider the following using ReplaceRepeated:

pattremove = 
  ReplaceRepeated[{start___, x1_, x2_, x1_, x2_, end___} :> {start, x1, x2, end}];

pattremove@{a1, a2, a3, x1, x2, x1, x2, x1, x2, x1, x2, x1, x2, z1, z2}
(* Out: {a1, a2, a3, x1, x2, z1, z2} *)

pattremove@{1, 2, 3, 4, 3, 4, 5, 6, 5, 6, 7}
(* Out: {1, 2, 3, 4, 5, 6, 7} *)

pattremove@{1, 2, 3, 4, 3, 4, 5, 6, 5, 6, 5, 6, 5, 6, 7}
(* Out: {1, 2, 3, 4, 5, 6, 7} *)