0
$\begingroup$

I am trying to fix the plot in the manipulate to be continuous. I used Exclusion->None and adjusted the PlotPoints too. Nothing has worked so far. Could anybody help me to have a continuous plot?

R = 8.3145;
S = 0.2;
Solve[{(S - 2 vo)^2 (-3 + S - vo) + 
       Exp[(-i + (T + 273) j)/(R (T + 273))]*Sqrt[k] vo == 0}, {vo}, 
    Reals][[3]][[1]][[2]]

Manipulate[
 Plot[%444, {T, 200, 900}, 
  AxesLabel -> {Temperature[\[Degree]C], \[Delta]}, 
  Exclusions -> None], {{k, 0.21, "pO2"}, {0.21, 0.01, 0.0015, 
   0.00003}, 
  Setter}, {{i, -500000, 
   "\[CapitalDelta]H\[Degree]"}, -500000, -50000}, {{j, -500, 
   "\[CapitalDelta]S\[Degree]"}, -500, -100}]

enter image description here

$\endgroup$
2
  • 1
    $\begingroup$ Edit your post and include the code formatted code for the Manipulate. $\endgroup$ – Edmund May 7 '20 at 23:49
  • $\begingroup$ Sorry about that, I just edited my question with Manipulate code. $\endgroup$ – user72564 May 8 '20 at 2:59
1
$\begingroup$

The problem isn't with Plot, it's with the function you're plotting. Note that %444 /. {k -> 0.21, i -> -500000, j -> -500, T -> 690} returns undefined. This is due to the condition that follows the Root function. All of the conditions return False so the equation is left unevaluated. The solution to your equation consists of 6 possible solutions. My guess is that one of the other solutions fills in the missing part.

It looks like the fifth solution fills in the missing part.

R = 8.3145;
S = 0.2;
nsol = vo /. 
  Solve[{(S - 2 vo)^2 (-3 + S - vo) + 
      Exp[(-i + (T + 273) j)/(R (T + 273))]*Sqrt[k] vo == 0}, {vo}, 
   Reals]
Manipulate[
 Plot[{
   With[{k = k, i = i, j = j}, nsol[[3]]],
   With[{k = k, i = i, j = j}, nsol[[5]]]
   },
  {T, 200, 900},
  PlotStyle -> ColorData[97][1]
  ],
 {{k, 0.21, "p02"}, {0.21, 0.01, 0.0015, 0.00003}},
 {{i, -500000, "\[CapitalDelta]H"}, -500000, -50000},
 {{j, -500, "dS"}, -500, -100}
 ]

I added in PlotStyle -> ColorData[97][1] so that both parts would plot in the same colour, but if you prefer that they plot in different colours, you can simply remove that line.

enter image description here

Also, as Edmund mentioned, please include all of the code whenever possible rather than a screenshot. If you forget, you can always edit the question later to include it. This makes it much easier for people to help out because we don't have to retype all of the code in the screenshot, we can just copy and paste.

$\endgroup$
1
  • $\begingroup$ Thank you so much for helping me to solve this. Sorry about the coding I forgot to include. I learned a new thing today! $\endgroup$ – user72564 May 8 '20 at 2:56

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.