0
$\begingroup$

I have the following equation which I want to solve it for r:

TGB5 = (-((2 q^2)/r^5) + 2/r + (16 P \[Pi] r)/3)/(4 \[Pi]);

rlarge5 = Last[r /. Solve[TGB5 == T, r, Reals]] // Normal

The answer is a root object:

Root[-3 q^2 + 3 #1^4 - 6 [Pi] T #1^5 + 8 P [Pi] #1^6 &, 4]

Now, this function of r should be expanded about T=Infinity. But Mathematica gives the error:

rser5 = Series[rlarge5, {T, Infinity, 4}] // Normal

Series::nmer: Root[-3 q^2+3 #1^4-6 [Pi] T #1^5+8 P [Pi] #1^6&,4] is not a meromorphic function of T at [Infinity].

Is there anyway to expand this root object?

$\endgroup$
  • $\begingroup$ What version are you using? I ran your code on 12.1. I got a warning Root::sbr: Because of branch cuts, the series may represent a different root of -3 q^2 T+3 T #1^4-6 \[Pi] #1^5+8 P \[Pi] T #1^6& for some values of {P,q,T}. but also an answer that's too long to post. $\endgroup$ – N.J.Evans Apr 9 at 13:31
  • 1
    $\begingroup$ @ Evans Thanks. I run it on 11 and there is no answer. Only the error. $\endgroup$ – Soodeh Z. Apr 9 at 13:34
5
$\begingroup$
$Version

(* "12.1.0 for Mac OS X x86 (64-bit) (March 14, 2020)" *)

Clear["Global`*"]

TGB5 = (-((2 q^2)/r^5) + 2/r + (16 P π r)/3)/(4 π);

rlarge5 = Last[r /. Solve[TGB5 == T, r, Reals]] // Normal

(* Root[-3 q^2 + 3 #1^4 - 6 π T #1^5 + 8 P π #1^6 &, 4] *)

Since all variables are real and Series takes Assumptions,

rser5 = Assuming[Element[{P, q, T}, Reals],
  Series[rlarge5, {T, Infinity, 4}] // Normal // Simplify]

(* Root::sbr: Because of branch cuts, the series may represent a different 
 root of -3 q^2 T+3 T #1^4-6 π #1^5+8 P π T #1^6& for some values of {P,q,T}.

(8 (-1)^(2/5) 2^(1/5) π^(3/5)
     q^4 (-252 P + 2240 P^3 π^2 q^2 - 225 π T^2) - 
   3840 (-1)^(1/5) 2^(3/5) P^2 π^2 q^4 T^(2/5) Abs[q]^(6/5) - 
   12800 (-1)^(4/5) 2^(2/5) P^2 π^(14/5) q^4 T^(6/5) Abs[q]^(8/5) + 
   2400 P π^(7/5) q^2 T^(4/5) Abs[q]^(12/5) + 
   7200 (-1)^(3/5) 2^(4/5) P π^(11/5) q^2 T^(8/5) Abs[q]^(14/5) - 
   3 (-1)^(1/5) 2^(3/5) T^(
    2/5) (-21 + 3200 P^2 π^2 q^2 + 4000 P π^3 q^2 T^2) Abs[q]^(
    16/5) + 360 2^(2/5) (-π)^(4/5) T^(6/5) Abs[q]^(18/5) + 
   1800 π^(7/5) T^(4/5) (2 P + 5 π T^2) Abs[q]^(22/5) + 
   45000 (-1)^(3/5) 2^(4/5) π^(16/5) T^(18/5) Abs[q]^(
    24/5))/(90000 π^(17/5) T^(19/5) Abs[q]^(22/5)) *)

Version 12.1 finds a series expression; however, this has not considered the conditions for the selected root and issues a warning. Using the ConditionalExpression,

rlarge5r = Last[r /. Solve[TGB5 == T, r, Reals]]

enter image description here

rser5r = Series[rlarge5r, {T, Infinity, 4}] // Normal // Simplify

(* (40 2^(2/5) q^2 (9 (-π)^(4/5) - 320 (-1)^(4/5) P^2 π^(14/5) q^2) T^(
    6/5) + 7200 (-1)^(3/5) 2^(4/5) P π^(11/5) q^2 T^(8/5) Abs[q]^(6/5) - 
   3 (-1)^(1/5) 2^(3/5) T^(
    2/5) (-21 + 4480 P^2 π^2 q^2 + 4000 P π^3 q^2 T^2) Abs[q]^(8/5) + 
   8 (-1)^(2/5) 2^(1/5) π^(
    3/5) (-252 P + 2240 P^3 π^2 q^2 - 225 π T^2) Abs[q]^(12/5) + 
   3000 π^(7/5) T^(4/5) (2 P + 3 π T^2) Abs[q]^(14/5) + 
   45000 (-1)^(3/5) 2^(4/5) π^(16/5) T^(18/5) Abs[q]^(
    16/5))/(90000 π^(17/5) T^(19/5) Abs[q]^(14/5)) *)

This is a slightly simpler form and avoids the warning.

| improve this answer | |
$\endgroup$
  • $\begingroup$ @Hanlon Thanks for the answer. Could you please take a look at my answer to this question? $\endgroup$ – Soodeh Z. Apr 9 at 21:25
2
$\begingroup$

In Mathematica 12.1, the following code gives the right answer:

r /. Last[AsymptoticSolve[TGB5 == T, r, {T, Infinity, 8}]] // Expand

which is:

 -((4 P^2)/(9 \[Pi]^3 T^5)) + (128 P^4 q^2)/(81 \[Pi] T^5) - P/(
 3 \[Pi]^2 T^3) - 1/(2 \[Pi] T) + (3 T)/(4 P)

I do not know why the answer from AsymptoticSolve command is too far from what the Series command computes (Please see Hanlon answer.). Does any one know?

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.