5
$\begingroup$

I saw this beautiful, hypnotic set of concentric circles rotating in 3D around the origin.

enter image description here

I thought I could produce the same on Mathematica, but terribly failed. So far this is what I tried:

Graphics[Table[{AbsoluteThickness[5], Lighter@Hue[0.42 + 0.1 r], Circle[{0, 0}, r]}, {r, 0, 10, 0.5}], Background -> Black]

enter image description here

The above code produces a nice set of circles. I used RotateTransform inside Graphics3D too, but it says CircleBox is not a Graphics3D primitive. I do not know how to implement further.

Any idea or hint is appreciated.

Improve this question
$\endgroup$

1 Answer 1

Reset to default
7
$\begingroup$

Circles are really 2D objects, unfortunately you can't use them on Graphics3D like that.

You can start with this:

Table[
  Graphics3D[
   Table[{Hue[h],
     Rotate[Tube@Table[h {Sin[t], 0, Cos[t]}, {t, 0, 2 Pi, Pi/50}],
      u h, {0, 0, 1}]},
    {h, 1/20, 1, 1/20}],
   Lighting -> {{"Ambient", White}}, ViewPoint -> Front, 
   ViewAngle -> 30 Degree, Boxed -> False, Background -> Black],
  {u, 0, 5 Pi, Pi/10}] // ListAnimate

enter image description here

This just creates your rings as 3D Tubes, sets lighting as intended and rotates these rings.

Improve this answer
$\endgroup$
4
  • 2
    $\begingroup$ +1, that is nice! I should have realised Tubes are the objects to be used, thanks. I will wait for more submissions until I accept this. $\endgroup$
    – exp ikx
    Apr 5, 2020 at 18:02
  • $\begingroup$ Is it a mere coincidence that your profile pic looks very relevant for this question? $\endgroup$
    – exp ikx
    Apr 6, 2020 at 4:24
  • $\begingroup$ @expikx Heh, it's purely coincidental. :) $\endgroup$
    – kirma
    Apr 6, 2020 at 6:53
  • $\begingroup$ Haha, I'm just kidding :) $\endgroup$
    – exp ikx
    Apr 6, 2020 at 7:02

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.