4
$\begingroup$

I am trying to find InverseFourierTransform of the following function, but the code below does not give me a result. I do not get any error messages but the calculation just does not end. Any Help? Thanks in advance.

InverseFourierSinTransform[1/(w^6 (w^2 + b)), w, r, 
 Assumptions -> {w > 0, b > 0}, FourierParameters -> {1, -1}]

Note that if 1/(w (w^2 + b))I get the result right way.

$\endgroup$
4
$\begingroup$

Apart function helps:

$Version
(*12.1.0 for Microsoft Windows (64-bit) (March 14, 2020)*)

FUNC = InverseFourierSinTransform[Apart[1/(w^6 (b + w^2)), w], w, r, 
Assumptions -> {r > 0, b > 0}, FourierParameters -> {1, -1}]

(*(r (-7200 - 2200 b r^2 - 137 b^2 r^4 + 
60 EulerGamma (120 + 20 b r^2 + b^2 r^4) + 
60 (120 + 20 b r^2 + b^2 r^4) Log[r]))/(7200 b^3 \[Pi]) + 
MeijerG[{{1/2}, {}}, {{1/2, 1/2}, {0}}, (b r^2)/4]/(
2 b^(7/2) Sqrt[\[Pi]])*)

FUNC // Simplify // Expand

(*-(r/(b^3 \[Pi])) + (EulerGamma r)/(b^3 \[Pi]) - (11 r^3)/(
36 b^2 \[Pi]) + (EulerGamma r^3)/(6 b^2 \[Pi]) - (137 r^5)/(
7200 b \[Pi]) + (EulerGamma r^5)/(120 b \[Pi]) + (r Log[r])/(
b^3 \[Pi]) + (r^3 Log[r])/(6 b^2 \[Pi]) + (r^5 Log[r])/(
120 b \[Pi]) + MeijerG[{{1/2}, {}}, {{1/2, 1/2}, {0}}, (b r^2)/4]/(
2 b^(7/2) Sqrt[\[Pi]]) *)

$$\text{InverseFourierSinTransform}\left[\frac{1}{w^6 \left(b+w^2\right)},w,r\right]=\\-\frac{r}{b^3 \pi }+\frac{\gamma r}{b^3 \pi }-\frac{11 r^3}{36 b^2 \pi }+\frac{\gamma r^3}{6 b^2 \pi }-\frac{137 r^5}{7200 b \pi }+\frac{\gamma r^5}{120 b \pi }+\frac{r \log (r)}{b^3 \pi }+\frac{r^3 \log (r)}{6 b^2 \pi }+\frac{r^5 \log (r)}{120 b \pi }+\frac{G_{1,3}^{2,1}\left(\frac{b r^2}{4}| \begin{array}{c} \frac{1}{2} \\ \frac{1}{2},\frac{1}{2},0 \\ \end{array} \right)}{2 b^{7/2} \sqrt{\pi }}$$

| improve this answer | |
$\endgroup$
  • $\begingroup$ What does Apart do exactly? $\endgroup$ – Johe Apr 3 at 8:44
  • 1
    $\begingroup$ Try: Apart[1/(w^6 (b + w^2)), w] and see, or Read Documentation. $\endgroup$ – Mariusz Iwaniuk Apr 3 at 8:46
  • $\begingroup$ Ok. Thanks.Would you please tell me Why your Assumptions -> {r > 0, b > 0} not Assumptions -> {k > 0, b > 0}? $\endgroup$ – Johe Apr 3 at 8:50
  • $\begingroup$ With yours assumption works to,Try:{InverseFourierSinTransform[Apart[1/(w^6 (b + w^2)), w], w, r, Assumptions -> {w > 0, b > 0}, FourierParameters -> {1, -1}], InverseFourierSinTransform[Apart[1/(w^6 (b + w^2)), w], w, r, Assumptions -> {w >= 0, b > 0}, FourierParameters -> {1, -1}]} $\endgroup$ – Mariusz Iwaniuk Apr 3 at 8:56
2
$\begingroup$

Amplifying on Mariusz Iwaniuk's answer

$Version

(* "12.1.0 for Mac OS X x86 (64-bit) (March 14, 2020)" *)

Clear["Global`*"]

ift = InverseFourierSinTransform[1/(w^6 (w^2 + b)) // Apart, w, r, 
  Assumptions -> {b > 0}, FourierParameters -> {1, -1}]

(* (1/(7200 b^3 π))
 r (-7200 - 2200 b r^2 - 137 b^2 r^4 + 
    60 EulerGamma (120 + 20 b r^2 + b^2 r^4) + 
    60 (120 + 20 b r^2 + b^2 r^4) Log[r]) + 
 MeijerG[{{1/2}, {}}, {{1/2, 1/2}, {0}}, (b r^2)/4]/(2 b^(7/2) Sqrt[π]) *)

Using FunctionExpand to convert the MeijerG

ift2 = ift // FunctionExpand // FullSimplify[#, {b > 0}] &

(* (1/(7200 b^4 π r))(b r^2 (7200 (-1 + EulerGamma) + 
     200 b (-11 + 6 EulerGamma) r^2 + b^2 (-137 + 60 EulerGamma) r^4 + 
     60 (120 + b r^2 (20 + b r^2)) Log[r]) - 
  3600 Sqrt[b r^2] ((2 CoshIntegral[Sqrt[b] r] - 
        2 (Log[r] + Floor[Arg[r]/(2 π)] (Log[1/r] + Log[r])) + 
        Log[r^2]) Sinh[Sqrt[b] r] - 
     2 Cosh[Sqrt[b] r] SinhIntegral[Sqrt[b] r])) *)

The function is defined only in the limit at r == 0

{ift, ift2} /. r -> 0 // Quiet

(* {Indeterminate, Indeterminate} *)

Limit[ift2, r -> 0]

(* 0 *)

The function is real when

FunctionDomain[{ift2, b > 0}, {b, r}] // FullSimplify

(* Sqrt[b] r > 0 *)

Then for r > 0

ift3 = ift2 // FullSimplify[#, {r > 0, b > 0}] &

(* (1/(7200 b^(
 7/2) π))(Sqrt[b]
    r (7200 (-1 + EulerGamma) + 200 b (-11 + 6 EulerGamma) r^2 + 
     b^2 (-137 + 60 EulerGamma) r^4 + 60 (120 + b r^2 (20 + b r^2)) Log[r]) - 
  7200 CoshIntegral[Sqrt[b] r] Sinh[Sqrt[b] r] + 
  7200 Cosh[Sqrt[b] r] SinhIntegral[Sqrt[b] r]) *)

Plot3D[ift3, {b, 0, 5}, {r, 0, 10},
 PlotPoints -> 50,
 MaxRecursion -> 5,
 ClippingStyle -> None,
 AxesLabel -> Automatic,
 WorkingPrecision -> 20]

enter image description here

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.