Numerical computation of a double integral

Question

I wish to numerically evaluate a function of the form

$$ P(v_0) = \frac{e^{\int_0^{v_0}F(v)dv}}{\int_{-\infty}^{+\infty}e^{\int_0^{v_1}F(v)dv}dv_1} $$

In the denominator is the normalization constant which gives me the trouble.

The function $F$ is given by

$F(v) = -v+\frac{1}{1+\frac{v}{e^v-1}}-\frac{1}{1+\frac{ve^v}{e^v-1}}$

I can compute the nominator numerically:

P[v0_] := 
  Exp[NIntegrate[-v + 1/(1 + v/(-1 + E^v)) - 1/(
     1 + (E^v v)/(-1 + E^v)), {v, 0, v0}]];
Plot[P[v0], {v0, -20, 20}]

but can't manage to do it with the normalization constant included.

Any suggestions?

Answer 1

There's no need for finesse or truncation here:

F[v_] = -v + 1/(1 + v/(E^v - 1)) - 1/(1 + (v E^v)/(E^v - 1));
G[v1_?NumericQ] := Exp[NIntegrate[F[v], {v, 0, v1}]]
Gnorm = NIntegrate[G[v1], {v1, -\[Infinity], \[Infinity]}]
(*    2.87582    *)
P[v0_?NumericQ] := G[v0]/Gnorm

Answer 2

The function F decays so rapidly that it should be okay to truncate the domain of integration. For example, we have

NIntegrate[Q[v1], {v1, -30, 30}, PrecisionGoal -> 14]/ NIntegrate[Q[v1], {v1, -100, 100}, PrecisionGoal -> 14] - 1

2.66454*10^-15

So the following should have quite a few digits of precision:

F[v_] := -v + 1/(1 + v/(-1 + E^v)) - 1/(1 + (E^v v)/(-1 + E^v))
Q[v1_?NumericQ] := Exp[NIntegrate[F[v], {v, 0, v1}]];
const = NIntegrate[Q[v1], {v1, -30, 30}, PrecisionGoal -> 14]
P[v1_] := Q[v1]/const;

Answer 3

isn't the normalization constant the integral starting at 0 (otherwise, you need to find the function at -infinity where it blows up). So use the final value of F as the normalization constant and divide by it at the end.