4
$\begingroup$

I have a nested list of the form:

list = {{4., -18., 19.}, {3., 18., -5.}, {-5., -8., -15.}, {-20., 7., -16.}, {10., -13., -7.},
        {-12., -9., 17.}, {17., 19., 5.}, {-16., 9., 15.}, {11., -5., -14.}, {18., -10., 13.},
        {-3., 11., 12.}, {-6., 17., -8.}, {-18., 14., 1.}, {-19., -15., 10.}, {12., 18., -19.}, 
        {-8., 4., 7.}, {-8., -9., 4.}, {7., 17., -15.}, {12., -7., -14.}, {-10., -11., 8.},
        {2., -15., -11.}, {9., 6., 1.}, {-11., 20., -17.}, {9., -15., 13.}, {12., -7., -17.},
        {-18., -2., 20.}, {20., 12., 4.}, {19., 11., 14.}, {-16., 18., -4.}, {-1., -17., -19.},
        {-13., 15., 10.}, {-12., -14., -13.}, {12., -14., -7.}, {-7., 16., 10.}, {6., 10., 7.},
        {20., 14., -16.}, {-19., 17., 11.}, {-7., 1., -20.}, {-5., 12., 15.}, {-4., -9., -13.},
        {12., -11., -7.}, {-5., 19., -8.}, {1., 16., 17.}, {20., -14., -15.}, {13., -4., 10.},
        {14., 7., 10.}, {-5., 9., 20.}, {10., 1., -19.}, {-16., -15., -1.}, {16., 3., -11.},
        {-15., -10., 4.}, {4., -15., -3.}, {-10., -16., 11.}, {-8., 12., -5.}, {14., -6., 12.},
        {1., 6., 11.}, {-13., -5., -1.}, {-7., -2., 12.}, {1., -20., 19.}, {-2., -13., -8.}, 
        {15., 18., 4.}, {-11., 14., 9.}, {-6., -15., -2.}, {5., -12., -15.}, {-6., 17., 5.},
        {-13., 5., -19.}, {20., -1., 14.}, {9., -17., 15.}, {-5., 19., -18.}, {-12., 8., -10.}, 
        {-18., 14., -4.}, {15., -9., 13.}, {9., -5., -1.}, {10., -19., -14.}, {20., 9., 4.}, 
        {-9., -2., 19.}, {-5., 13., -17.}, {2., -10., -18.}, {-18., 3., 11.}, {7., -9., 17.},
        {-15., -6., -3.}, {-2., 3., -13.}, {12., 3., -2.}, {-2., -3., 17.}, {20., -15., -16.},
        {-5., -17., -19.}, {-20., -18., 11.}, {-9., 1., -5.}, {-19., 9., 17.}, {12., -2., 17.},
        {4., -16., -5.}};

I wish to first sort each sublist based on the absolute values(e.g. {4., -16., -5.} => {4., -5., -16.}) and then sort the sublists based on the first followed by the second element (based on absolute values for both the cases).

For example, considering the first 5 sublists the sorted list should be

listSorted5 = {{3., -5., 18.}, {4., -18., 19.}, {-5., -8., -15.},
               {-7., 10., -13.}, {7., -16., -20.}}

How can I do this?

$\endgroup$
4
$\begingroup$

How about

list // Map[SortBy[Abs]] // SortBy[#, ({Abs@#[[1]], Abs@#[[2]]} &)] &
$\endgroup$
2
  • $\begingroup$ Thanks. Actually, TableForm[ data // Map[SortBy[Abs]] // SortBy[#, ({Abs@#[[1]], Abs@#[[2]], Abs@#[[3]]} &)] &] is what is I needed. $\endgroup$ – Majis Mar 19 '20 at 20:34
  • 6
    $\begingroup$ list2 = SortBy[SortBy[#, Abs] & /@ list, Abs] $\endgroup$ – Bob Hanlon Mar 19 '20 at 21:10
3
$\begingroup$
sort = Map[SortBy @ Abs] /* SortBy[Abs @* Most]

sort @ list 

{{-1., -5., -13.}, {-1., -5., 9.}, {1., -5., -9.}, {1., 6., 9.}, {1., 6., 11.}, {1., -7., -20.}, {1., 10., -19.}, {-1., 14., 20.}, {1., 14., -18.}, {-1., -15., -16.}, {1., 16., 17.}, {-1., -17., -19.}, {1., 19., -20.}, {-2., -3., 17.}, {-2., 3., -13.}, {-2., 3., 12.}, {-2., -6., -15.}, {-2., -7., 12.}, {-2., -8., -13.}, {-2., -9., 19.}, {2., -10., -18.}, {2., -11., -15.}, {-2., 12., 17.}, {-2., -18., 20.}, {-3., 4., -15.}, {3., -5., 18.}, {-3., -6., -15.}, {-3., 11., 12.}, {3., -11., 16.}, {3., 11., -18.}, {4., -5., -16.}, {4., 7., -8.}, {4., -8., -9.}, {-4., -9., -13.}, {4., 9., 20.}, {-4., 10., 13.}, {4., -10., -15.}, {4., 12., 20.}, {-4., 14., -18.}, {4., 15., 18.}, {-4., -16., 18.}, {4., -18., 19.}, {5., -6., 17.}, {-5., -8., -15.}, {-5., -8., 12.}, {-5., -8., 19.}, {-5., 9., 20.}, {-5., 11., -14.}, {-5., 12., 15.}, {5., -12., -15.}, {-5., 13., -17.}, {5., -13., -19.}, {-5., -17., -19.}, {5., 17., 19.}, {-5., -18., 19.}, {6., 7., 10.}, {-6., -8., 17.}, {-6., 12., 14.}, {7., -9., 17.}, {-7., 10., -13.}, {-7., 10., 16.}, {7., 10., 14.}, {-7., -11., 12.}, {-7., 12., -17.}, {-7., 12., -14.}, {-7., 12., -14.}, {7., -15., 17.}, {7., -16., -20.}, {8., -10., -12.}, {8., -10., -11.}, {9., \ -11., 14.}, {-9., -12., 17.}, {-9., 13., 15.}, {9., 13., -15.}, {9., 15., -17.}, {9., 15., -16.}, {9., 17., -19.}, {-10., 11., -16.}, {-10., 13., 18.}, {10., -13., 15.}, {10., -14., -19.}, {10., -15., -19.}, {11., 14., 19.}, {-11., -17., 20.}, {11., 17., -19.}, {11., -18., -20.}, {-12., -13., -14.}, {12., 18., -19.}, {-14., -15., 20.}, {14., -16., 20.}, {-15., -16., 20.}}

Also

sort2 = SortBy[Abs @* Most] @* Map[SortBy @ Abs]

sort2 @ list == sort @ list

True

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.