How to merge dataset rows conditionally?

Question

I have dataset of the following form. I have processed the dates to be DateObjects and now would like to merge the hours per the date because sometimes multiple types of tasks were done on the same day.

I was a bit surprised there wasn't a built-in function to do this but perhaps there is and I missed it in the docs? Right now I thought I would ask for help before going too far down this path because I can see this getting very convoluted very quickly. Is there a more Mathematica-centric way to do this? In Python with pandas I'd probably use a for-loop & append a list with the sums.

comparelist = Partition[Range[Length@data],2,1]
MatchQ[data[#[[1]],"Date"],data[#[[2]],"Date"]] &/@ comparelist

{False,False,False,False,False,False,False,False,False,False,False,False,False,False,False,False,False,True,True,False,False,False,False,False,False,False,False,False,False,False,False,True,False,False,False,False,False,False,True,False,False,False,False,True,False,False,False,False,False,False,False,False,False,True,False,False,False,False,False,False,False,False,True,False,False,False,False,True}

Answer 1

dr = DateObject /@ DateRange[{2020, 1, 1}, DatePlus[{2020, 1, 1}, Quantity[15, "Days"]]];

SeedRandom[1]
data = Transpose[{RandomChoice[dr, 30], 
   Round[ RandomReal[10, 30], .1], 
   RandomChoice[{"app", "graphics", "research"}, 30]}]; 

ds = Dataset[AssociationThread[{"Date", "Hours", "Task"}, #] & /@ data];

ds[GroupBy["Date"], All, {"Hours", "Task"}]

ds[GroupBy["Date"], All, "Hours"][All, Total]

Alternatively, you can use GroupBy on data:

GroupBy[data, First -> Rest, 
     Apply[{Total @ #, DeleteDuplicates @ #2} &] @* Transpose] // Dataset

GroupBy[data, First -> (#[[2]] &), Total] // Dataset

Answer 2

While kglr's approach is correct, there is a more succinct one:

ds[GroupBy["Date"],Total,"Hours"]

The reason it works is because

ds[GroupBy["Date"],Total]

produces the total for every column in the grouped result, and "Hours" selects just the one we need.