1
$\begingroup$

I am trying to find the Inverse Laplace transform of a function I previously obtained from a Laplace transform, but the result obtained does not agree with the initial function. Why is this happening?

LaplaceTransform[2 z^3 Coth[z] Csch[z]^2, z, s] // FullSimplify
InverseLaplaceTransform[%, s, z] // FullSimplify
-(48/(-2 + s)^4) + 3 PolyGamma[1, -1 + s/2] + 
 1/8 s (12 PolyGamma[2, -1 + s/2] + s PolyGamma[3, -1 + s/2])
-2 E^(2 z) z (3 + z (9 + 4 z) + 3 Coth[z] (1 + 2 z - z Coth[z]))

The last line does not agree with the initial function I was transforming: 2 z^3 Coth[z] Csch[z]^2.

$\endgroup$
5
  • $\begingroup$ Have you tried substituting numerical values for z to verify that the expressions are not equivalent? $\endgroup$
    – mikado
    Mar 13, 2020 at 13:30
  • $\begingroup$ Yes, they are definitely different. You can plot those functions and check. $\endgroup$
    – Damian
    Mar 13, 2020 at 14:02
  • $\begingroup$ LaplaceTransform[TrigToExp[2 z^3* Coth[z] *Csch[z]^2] // Simplify, z, s] produces a big expression and InverseLaplace Transform fails with it, returning the input. $\endgroup$
    – user64494
    Mar 13, 2020 at 14:48
  • $\begingroup$ Which version of Mathematica are you using? $\endgroup$
    – mikado
    Mar 13, 2020 at 14:49
  • $\begingroup$ @mikado; Version 12.0 under Windows 10 32-bit on 64-bit machine. $\endgroup$
    – user64494
    Mar 13, 2020 at 15:00

1 Answer 1

3
$\begingroup$

It's seems a BUG in InverseLaplaceTransform.I checked in version 12.0 and 12.1. both occur.

If we try:

InverseLaplaceTransform[ s^2 PolyGamma[3, -1 + s/2], s, z](*Wrong Answer !!!*)
(* 0 *)

We can check and using identity for PolyGamma function:

func = FullSimplify[LaplaceTransform[2*z^3*Coth[z]*Csch[z]^2, z, s]] //
Expand
(*-(48/(-2 + s)^4) + 3 PolyGamma[1, -1 + s/2] + 
3/2 s PolyGamma[2, -1 + s/2] + 1/8 s^2 PolyGamma[3, -1 + s/2]*)

func1 = FullSimplify[
InverseLaplaceTransform[ func[[1 ;; 3]], s, z] + 
 Sum[1/8 InverseLaplaceTransform[s^2*6/(-1 + k + s/2)^4, s, 
    z], {k, 0, Infinity}], z > 0] // ExpToTrig // Simplify
(* 2 z^3 Coth[z] Csch[z]^2 *)

Result obtained does agree with the initial function.

EDITED:

RE: [CASE:4392492] Bug in Mathematica 12.1 (InverseLaplaceTransform)

It does appear that InverseLaplaceTransform is not behaving correctly/consistently. I have forwarded an issue report to our developers with the information you provided. I also included your contact information in my report.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.