Remove elements at certain positions from all sub-lists?

Question

Consider a big list where all the inner lists' lengths are the same

 list = {{x1, y1, z1, t1}, {x2, y2, z2, t2}, {x3, y3, z3, t3}, ...};
 elementNo = {4, 3, 2};

I want output like this,

{{x1}, {x2}, {x3}, ...}

That is, when I specify elementNo as {4, 3, 2}, I mean the elements at positions 2, 3 and 4 in the sub-lists should be removed -- I want the elements at position 1 only. When I specify elementNo as {2, 3}, I want

 {{x1, t1}, {x2, t2}, {x3, t3}, ...}

How can I do this?

Answer 1

Another option:

f[list_, pos_] := Module[{x = list},
  x[[All, pos]] = Sequence[];
  x]

Answer 2

f1[list_, spec_] := With[{sp = List /@ spec}, Delete[#, sp] & /@ list]

f1[list, {4, 3, 2}]
f1[list, {2, 3}]

{{x1}, {x2}, {x3}}
{{x1, t1}, {x2, t2}, {x3, t3}}

f2[list_, spec_] := list[[ All, Complement[Range@Length@First@list, spec] ]]

f2[list, {4, 3, 2}]
f2[list, {2, 3}]

{{x1}, {x2}, {x3}}
{{x1, t1}, {x2, t2}, {x3, t3}}

Answer 3

Try this one

list = RandomInteger[50, {10, 4}]
new = {};
elemNo = {4, 3, 2};
new = Map[Delete[#, {{elemNo[[1]]}, {elemNo[[2]]}, {elemNo[[3]]}}] &,list]

Answer 4

Here's another alternative:

f[list_, pos_] := With[{p = pos ~Sort~ Greater}, Fold[# ~Drop~ {#2} &, #, p] & /@ list]

f[list, {2, 3}]
(* {{x1, t1}, {x2, t2}, {x3, t3}} *)

If you can guarantee that the positions to be dropped will be input in descending order, you can drop the sorting step.

Answer 5

list = {{x1, y1, z1, t1}, {x2, y2, z2, t2}, {x3, y3, z3, t3}};
elementNo = {4, 3, 2};

MapAt[Nothing, list, Thread[{All, elementNo}]]

{{x1}, {x2}, {x3}}

Answer 6

here is the way I would do it using my Excel mindset,

list = {{x1, y1, z1, t1}, {x2, y2, z2, t2}, {x3, y3, z3, t3}};
elementNo = {4, 3, 2};
todelete = {#} & /@ Sort@elementNo
tokeep = Delete[Range@Length@First@list, todelete]
remaining = Take[list, All, tokeep]

or something similar.

Answer 7

Another way, using Outer and Extract:

data = {{x1, y1, z1, t1}, {x2, y2, z2, t2}, {x3, y3, z3, t3}};
unwanted1 = {4, 3, 2};
unwanted2 = {2, 3};

extractComplement[data_List, spec_List] :=
  Module[{dataSize, subSize, survivors},
    dataSize = Length@data;
    subSize = Length@data[[1]];
    survivors = Outer[List, Range@dataSize, Complement[Range@subSize, spec]];
    Extract[data, #] & /@ survivors]

extractComplement[data, unwanted1]

{{x1}, {x2}, {x3}}

extractComplement[data, unwanted2]

{x1, t1}, {x2, t2}, {x3, t3}

Answer 8

If all sublists are indeed of the same length, use Transpose:

Transpose@Delete[Transpose@list, List /@ elementNo]

{{x1}, {x2}, {x3}}

Note that you can use the shorthand notation for Transpose, which makes the code really short:

With other elementNo:

elementNo = {3, 2};
Transpose@Delete[Transpose@list, List /@ elementNo]

{{x1, t1}, {x2, t2}, {x3, t3}}

Answer 9

list = {{x1, y1, z1, t1}, {x2, y2, z2, t2}, {x3, y3, z3, t3}};

ps = {4, 3, 2};

Since Version 13.1 there is ReplaceAt:

ReplaceAt[list, _ -> Nothing, Thread[{All, ps}]]

{{x1}, {x2}, {x3}}

ReplacePart[list, {_, Alternatives @@ ps} -> Nothing]

{{x1}, {x2}, {x3}}

Answer 10

Using ArrayRules and Select:

list = {{x1, y1, z1, t1}, {x2, y2, z2, t2}, {x3, y3, z3, t3}};
ps = {4, 3, 2};

Values@Select[Rule[Last@#[[1]], {#[[2]]}] & /@ Most@ArrayRules[list], 
FreeQ[#[[1]], Alternatives @@ ps] &]

(*{{x1}, {x2}, {x3}}*)

Or using Table:

Table[If[Or @@ Thread[j == ps], Nothing, list[[i, j]]], {i, #}, {j, #}] &@Length@list

(*{{x1}, {x2}, {x3}}*)