Using a given colour table with Image?

Question

Context

I would like to represent large images with a given colour table.

Now, if I use Image

dat = RandomReal[{0, 1}, {1024, 1024}];
dat // Image; // Timing

(* ==> {0.000027, Null} *)

its fast, but in grayscales; on the other hand if I use, say MatrixPlot

dat // MatrixPlot[#, ColorFunction -> "Temperature"] &
dat // MatrixPlot[#, ColorFunction -> "Temperature"] &; // Timing

(* ==> {1.5748, Null} *)

its in colour, but its slow.

Question

Is there a method to get the best of both worlds? (i.e. Speed and chosen colour table).

Thank you for your help.

Answer 1

I think I finally succeeded in creating something faster.

Edit: now ~40X faster than ArrayPlot.

renderImage[
  array_?MatrixQ,
  cf_,
  q_Integer: 2048,
  opts : OptionsPattern[Image]
] := 
  Module[{tbl},
    tbl = List @@@ Array[cf, q, {0`, 1`}] // N // Developer`ToPackedArray;
    Image[tbl[[# + 1]] & /@ Round[(q - 1`) array], opts]
  ]

A test of function:

dat = Map[Mean, ImageData[Import["ExampleData/lena.tif"]], {2}];

ArrayPlot[dat, ColorFunction -> "Rainbow"]

renderImage[dat, ColorData["Rainbow"], ImageSize -> 300]

A test of speed:

big = RandomReal[1, {1500, 1500}];

ArrayPlot[big, ColorFunction -> "Rainbow"] // Timing // First

renderImage[big, ColorData["Rainbow"], ImageSize -> 300] // Timing // First

2.325

0.0624

And this time that's correct timing data.

---

Update

I have added a parameter q to control the number of quantization steps used. It arbitrarily defaults to 2048 which appears to be visually sufficient for most schemes and images. Examples of effect on quality and timing:

renderImage[dat, ColorData["Rainbow"], #, ImageSize -> 300] & /@ {7, 10000}

Needs["GeneralUtilities`"]

BenchmarkPlot[
 {renderImage[big, ColorData["Rainbow"], #] &},
 Identity,
 5^Range[9]
]

Answer 2

This answer was posted in error. Nevertheless I think the information below is helpful.

---

I believe the fastest general method is Raster, like this:

Graphics[Raster[RandomReal[1, {10, 20}], ColorFunction -> "Rainbow"]]

---

Actually, this isn't any faster than MatrixPlot, it's just different. With MatrixPlot the time is spent when the graphic is created, and with Raster it is spent when it is displayed:

Timing[g1 = MatrixPlot[dat, ColorFunction -> "Temperature"];]
Timing[g2 = Graphics[Raster[dat, ColorFunction -> "Temperature"]];]

{0.639, Null}

{0., Null}

To see the rendering time set:

SetOptions[$FrontEndSession, EvaluationCompletionAction->"ShowTiming"]

Then:

g1

g2

and you will see that g1 displays immediately, whereas g2 takes about as long to render as it did to create g1.