Removing a nested list associated with a key and inserting into a new list

Question

I'm trying to remove nested lists that are associated with a key

a = {{1, 2, 3, 4} -> 1, {5, 6, 7, 8} -> 1, {9, 10, 11, 12} -> 2, {13, 14, 15, 16} -> 2};

In order to create two separate lists where;

b contains the nested lists associated with the key 1, but without the key;

c contains the nested lists associated with the key 2, but without the key.

Would anybody be able to help?

Thanks!

Answer 1

You can use GroupBy:

{b, c} = GroupBy[a, Last, Keys] /@ {1, 2}

{{{1, 2, 3, 4}, {5, 6, 7, 8}},
{{9, 10, 11, 12}, {13, 14, 15, 16}}}

Alternatively, you can use Merge after reversing each element of a:

{b2, c2} = Values @ Merge[Identity] @ (Reverse /@ a) ;
{b2, c2} == {b, c}

True

You can also get the same result using Cases:

{b3, c3} = Cases[a, Rule[p_, #] :> p] & /@ {1, 2} 
{b3, c3} == {b, c}

True

Answer 2

With Query.

Query[GroupBy[Values -> Keys] /* KeySort /* Values]@a

or without

Values@KeySort@GroupBy[Values -> Keys]@a

Both give

{{{1, 2, 3, 4}, {5, 6, 7, 8}}, 
 {{9, 10, 11, 12}, {13, 14, 15, 16}}}

KeySort ensures the key sets are order by their value.

Hope this helps.