The code FourierTransform[Abs[Sin[t]], t, w] gives me a timeout like "This computation has exceeded the time limit for your plan."
What indeed is the FT of $|\sin(x)|$ ? Why can't Mathematica compute it ?
$\begingroup$
$\endgroup$
3
2 Answers
$\begingroup$
$\endgroup$
9
Abs isn't analytic, and using it here seems to lead FourierTransform to get lost in the complex plane. Use RealAbs:
FourierTransform[RealAbs[Sin[t]], t, w]
yielding:
Since the function is periodic, its transform is a train of delta functions. Something like FourierSeries might be more illuminating here. Maybe something like:
ComplexExpand[FourierSeries[RealAbs[Sin[t]], t, 10]]
yielding:
is what you want.
-
$\begingroup$ thanks for the answer! could I get further insight by perhaps getting the magnitude of this complex result?
Abs[%]does not seem to work because of the infinite sum. $\endgroup$– mlg556Feb 13, 2020 at 15:29 -
$\begingroup$ The result of FourierTransform[RealAbs[Sin[t]], t, w] is [CASE:4370384] reported by me on 08.01.20 This result is not a closed-form expression, but an analytic expression (see en.wikipedia.org/wiki/Closed-form_expression ). It is difficult to work with it. I was answered that the Mathematica devolopers were informed about that. $\endgroup$ Feb 13, 2020 at 16:32
-
1$\begingroup$ @user64494 : what closed-form do you expect for an infinite train of delta functions? $\endgroup$ Feb 13, 2020 at 17:37
-
1$\begingroup$ @user64494 : but it gives something that appears to be a correct answer. What's wrong with that? $\endgroup$ Feb 13, 2020 at 20:42
-
3$\begingroup$ @user64494: it exists in the pragmatic sense that we use in applied physics, and my
FourierSeriesresult along with @mikado'sDiracCombresult are perhaps better representations. $\endgroup$ Feb 13, 2020 at 21:50
$\begingroup$
$\endgroup$
2
You can obtain a simple expression using the convolution theorem. A single cycle of the waveform is given by
sig = Sin[t] UnitBox[t/π - 1/2]
This has a relatively simple Fourier Transform
spec = FullSimplify[FourierTransform[sig, t, ω]]
(* -((1 + E^(I π ω))/(Sqrt[2 π] (-1 + ω^2))) *)
We can convert our single cycle into a periodic signal by convolution with a Dirac Comb. This transforms to another Dirac comb
combspec = FourierTransform[DiracComb[t/π], t, ω]
(* Sqrt[π/2] DiracComb[ω/2] *)
By the convolution theorem (this probably needs multiply by a something like 2π), the Fourier transform of periodic signal is given by
Assuming[ω/2 ∈ Integers, FullSimplify[combspec*spec]]
(* DiracComb[ω/2]/(1 - ω^2) *)
Note that we can simplify the factor in front of the comb, as its value only needs to be correct for cases where the comb is non-zero.
-
$\begingroup$ However, the actions of FourierTransform and InverseFourierTransform on DiracDelta related functions are not reliable and correct in many cases (see that recent discussion mathematica.stackexchange.com/questions/212352/… ) . $\endgroup$ Feb 13, 2020 at 21:43
-
2$\begingroup$ With this excellent answer, we now have three different approaches yielding equivalent results. $\endgroup$ Feb 13, 2020 at 22:46
Abs[Cos[t]]in his "pictorial dictionary". Adjusting for his eccentric scaling, it's the same as the series in the answers below, but with signs of terms alternating to get the phasing right. $\endgroup$