How to calculate the degree of $∠FEB$ under this geometric scene

Question

I want to calculate the $∠FEB$ in the figure below, but I can't solve this question with GeometricScene function.

What can I do to find the answers to these questions in a general way?

GeometricScene[{"A", "B" -> {-1, 0}, "C" -> {1, 0}, "E", 
  "F"}, {Triangle[{"A", "B", "C"}], 
  PlanarAngle[{"B", "A", "C"}] == 20 °, 
  PlanarAngle[{"A", "B", "C"}] == 80 °, 
  PlanarAngle[{"A", "C", "B"}] == 80 °, Line[{"A", "F", "B"}],
   Line[{"A", "E", "C"}], Triangle[{"E", "B", "F"}], 
  PlanarAngle[{"E", "B", "F"}] == 20 °, 
  PlanarAngle[{"E", "C", "F"}] == 30 °}]
RandomInstance[%]
FindGeometricConjectures[%, 
  PlanarAngle[{__}] == _?NumericQ]["Conclusions"]

After this processing, we can get the figure:

But how to get the degree of $∠FEB$.

Answer 1

FindGeometricConjectures[
 RandomInstance[
  GeometricScene[{"A", "B" -> {-1, 0}, "C" -> {1, 0}, "E", 
    "F"}, {Triangle[{"A", "B", "C"}], 
    PlanarAngle[{"C", "A", "B"}] == 20 °, 
    PlanarAngle[{"A", "B", "C"}] == 80 °, 
    PlanarAngle[{"A", "C", "B"}] == 80 °, 
    Line[{"A", "F", "B"}], Line[{"A", "E", "C"}], 
    Triangle[{"E", "B", "F"}], 
    PlanarAngle[{"E", "B", "F"}] == 20 °, 
    PlanarAngle[{"E", "C", "F"}] == 30 °}]]]

and shows angle BEF to equal 30 degrees.

Apologies for the presentation of my code. I really have no idea how everybody's presentation looks so awesome :(

Answer 2

In your case, you can't get the result of PlanarAngle[{"B", "E", "F"}] == 30\[Degree] because there are two angles that are 30\[Degree]. By the following codes we can see that the result relevant is PlanarAngle[{"B", "E", "F"}] == PlanarAngle[{"E", "C", "F"}] == 30\[Degree] :

GeometricScene[{"A", "B" -> {-1, 0}, "C" -> {1, 0}, "E", 
      "F"}, {Triangle[{"A", "B", "C"}], 
      PlanarAngle[{"B", "A", "C"}] == 20 \[Degree], 
      PlanarAngle[{"A", "B", "C"}] == 80 \[Degree], 
      PlanarAngle[{"A", "C", "B"}] == 80 \[Degree], Line[{"A", "F", "B"}],
       Line[{"A", "E", "C"}], Triangle[{"E", "B", "F"}], 
      PlanarAngle[{"E", "B", "F"}] == 20 \[Degree], 
      PlanarAngle[{"E", "C", "F"}] == 30 \[Degree]}];
    t = RandomInstance[%]
    FindGeometricConjectures[t]["Conclusions"]

So you can see why FindGeometricConjectures[t, PlanarAngle[{__}] == _?NumericQ]["Conclusions"] doesn't work: the out put is _PlanarAngle == _PlanarAngle ==_ so _PlanarAngle == _ doesn't match, and it's easy to give a general solution to this circumstances: using

     FindGeometricConjectures[t,Equal[_PlanarAngle..,_?NumericQ]]["Conclusions"] 

, and it gives

     {PlanarAngle[{"B", "E", "F"}] == PlanarAngle[{"E", "C", "F"}] == 30 \[Degree],
     PlanarAngle[{"C", "B", "E"}] == 60 \[Degree]}

as we wanted.

Answer 3

If you're not interested in a proof, but just want to measure the angle in a given instance of a scene:

scene = GeometricScene[{"A", "B" -> {-1, 0}, "C" -> {1, 0}, "E", 
   "F"}, {Triangle[{"A", "B", "C"}], 
   PlanarAngle[{"B", "A", "C"}] == 20 °, 
   PlanarAngle[{"A", "B", "C"}] == 80 °, 
   PlanarAngle[{"A", "C", "B"}] == 80 °, 
   Line[{"A", "F", "B"}], Line[{"A", "E", "C"}], 
   Triangle[{"E", "B", "F"}], 
   PlanarAngle[{"E", "B", "F"}] == 20 °, 
   PlanarAngle[{"E", "C", "F"}] == 30 °}]
instance = RandomInstance[scene]

The coordinates of the points can be extracted like this:

instance[[1, 1]]

{"A" -> {1.05443*10^-16, -5.67128}, "B" -> {-1., 0.}, "C" -> {1., 0.}, "E" -> {0.532089, -2.65366}, "F" -> {-0.652704, -1.96962}}

You can measure the angle in a number of different ways:

(TriangleMeasurement[{"B", "E", "F"}, {"InteriorAngle", "E"}]/N[Degree]) /. instance[[1, 1]]

(PlanarAngle["E" -> {"B", "F"}]/N[Degree]) /. instance[[1, 1]]

You can repeat the experiment a number of times with different instances.