5
$\begingroup$

This is my current homework problem. I have completed parts a and b, but am now stuck on part c. I'm not sure what it means by plot the trajectories with different initial conditions, nor am I 100% sure how to do that. I know because of my positive eigenvalues that the solution will be unstable but after that I'm lost. Any advice would be really great.

enter image description here

$\endgroup$
11
$\begingroup$

You could try NDSolve then ParametricPlot3D

enter image description here

Manipulate[
 Module[{a = 0.25, b = 0.5, ode1, ode2, ode3, x, y, z, t},
  ode1 = x'[t] == -y[t] - z[t];
  ode2 = y'[t] == x[t] + a y[t];
  ode3 = z'[t] == b + z[t] (x[t] - c);
  sol = NDSolve[{ode1, ode2, ode3, x[0] == x0, y[0] == y0, 
     z[0] == z0}, {x[t], y[t], z[t]}, {t, 0, maxTime}, MaxSteps -> Infinity];
  ParametricPlot3D[{x[t], y[t], z[t]} /. sol, {t, 0, maxTime}, 
   PlotRange -> {{-15, 15}, {-15, 15}, {-10, 30}}, 
   AxesLabel -> {"x(t)", "y(t)", "z(t)"}, BaseStyle -> 12,
   ImageSize -> 400, PerformanceGoal -> "Quality", Mesh -> None]
  ],
 {{x0, .1, "x(0)"}, 0, 2, .1, Appearance -> "Labeled", ImageSize -> Tiny},
 {{y0, .1, "y(0)"}, 0, 1, .1, Appearance -> "Labeled", ImageSize -> Tiny},
 {{z0, .5, "z(0)"}, 0, 2, .1, Appearance -> "Labeled", ImageSize -> Tiny},
 {{c, 6.5, "c"}, 0, 7, .1, Appearance -> "Labeled", ImageSize -> Tiny},
 {{maxTime, 200, "time"}, 0.1, 250, .1, Appearance -> "Labeled", ImageSize -> Tiny},
 TrackedSymbols :> {x0, y0, z0, c, maxTime},
 ContinuousAction -> True,
 Alignment -> Center,
 SynchronousUpdating -> True,
 SynchronousInitialization -> True,
 FrameMargins -> 1, ImageMargins -> 1,
 ControlPlacement -> Left
 ]
$\endgroup$

Not the answer you're looking for? Browse other questions tagged or ask your own question.