7
$\begingroup$ 
x = {4, 1, 2, 5, 6, 7}
y = {1, 2, 4, 5, 6, 9}

There are two lists x and y. How to find out these positions of the elements in list x are smaller than those in corresponding list y and get the following results:

{2, 3, 6}
Improve this question
$\endgroup$
1
  • 1
    $\begingroup$ Just for fun: SparseArray[Ramp[y-x]]["NonzeroPositions"] $\endgroup$
    – user1066
    Apr 10 at 13:30

5 Answers 5

Reset to default
8
$\begingroup$ 
Flatten@Position[Negative[x - y], True]

Also possible:

Flatten@Position[x - y, _?(# < 0 &)]

or, as suggested by J.M., 

Flatten[Position[x - y, _?Negative]]
Improve this answer
$\endgroup$
4
  • 1
    $\begingroup$ +1, nice use of Negative! $\endgroup$
    – corey979
    Feb 3, 2020 at 13:13
  • $\begingroup$ @corey979 Thanks, I wonder why it is not called NegativeQ rather than Negative btw... ! $\endgroup$
    – anderstood
    Feb 3, 2020 at 13:15
  • 2
    $\begingroup$ @anders, because Negative[] and similar functions don't have to immediately evaluate to True/False (while *Q[] functions do so), which makes them usable in assumptions like Assuming[Negative[x], Simplify[UnitStep[x]]]. (On that note, you can do your last one as Flatten[Position[x - y, _?Negative]]) $\endgroup$
    – J. M.'s persistent exhaustion ♦
    Feb 3, 2020 at 13:26
  • $\begingroup$ @J.M. Thank you for the explanation! $\endgroup$
    – anderstood
    Feb 3, 2020 at 13:28
8
$\begingroup$ 
Flatten @ Position[Less @@@ Transpose[{x, y}], True]
Improve this answer
$\endgroup$
1
8
$\begingroup$ 
PositionIndex[Sign[x - y]] @ -1

{2, 3, 6}

Also

PositionIndex[UnitStep[x - y]] @ 0 (* thanks: J.M. *)

{2, 3, 6}

PositionIndex[Negative[x - y]] @ True (* thanks: anderstood *)

{2, 3, 6}

PositionIndex[Thread[x < y]]@True

{2, 3, 6}

If you prefer to have {} (rather than Missing["KeyAbsent", _]) as output when no positions satisfy the condition, you can use

Lookup[PositionIndex[Sign[x - y]], -1, {}]
Lookup[PositionIndex[UnitStep[x - y]], 0, {}]
Lookup[PositionIndex[Negative[x - y]], True, {}]
Lookup[PositionIndex[Thread[x < y]], True, {}]

for the four approaces above.

Improve this answer
$\endgroup$
3
  • 4
    $\begingroup$ Another equivalent for the first: Lookup[PositionIndex[UnitStep[x - y]], 0]. $\endgroup$
    – J. M.'s persistent exhaustion ♦
    Feb 3, 2020 at 13:37
  • 2
    $\begingroup$ Also: PositionIndex[Negative[x - y]][True] $\endgroup$
    – anderstood
    Feb 3, 2020 at 14:04
  • 1
    $\begingroup$ Thank you both J.M. and @anderstood. I added your suggestions. $\endgroup$
    – kglr
    Feb 3, 2020 at 14:09
2
$\begingroup$

Using Position and Condition:

Position[Transpose[{x, y}], {x_, y_} /; x < y]

(*{{2}, {3}, {6}}*)

Extract[Transpose[{x, y}], Position[Transpose[{x, y}], {x_, y_} /; x < y]]

(*{{1, 2}, {2, 4}, {7, 9}}*)

Or using SubsetPosition and Cases:

Transpose@SubsetPosition[Transpose[{x, y}], Cases[Transpose[{x, y}], {x_, y_} /; x < y]]

(*{{2}, {3}, {6}}*)
Improve this answer
$\endgroup$
1
$\begingroup$

Using MapIndexed:

x = {4, 1, 2, 5, 6, 7};
y = {1, 2, 4, 5, 6, 9};

MapIndexed[If[Less @@ #1, First@#2, Nothing] &, Transpose@{x, y}]

{2, 3, 6}

Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.