3
$\begingroup$

i was wondering if somebody could help me solving the following two coupled differential equations...

$$\Delta u_{xx}(x)=dw_{xxx}(x)+\frac{K}{EA}\Delta u(x) \\$$ $$-EI_\infty w_{xxxx}(x)+2d\,EA\;\Delta u_{xxx}(x)+q(x)=0$$

where $q(x)$ is a given function e.g. $q(x)=q_0\sin(\frac{\pi x}{l})$

I tried the following step in Mathematica

DSolve[{-EIinf w''''[x] + 2 d EA du'''[x] + q[x] == 0, du''[x] == d w'''[x] + 
K/EA du[x]}, {du, w}, x]

i also tried adding the boundary conditions to the DSolve function but it did not work either. The evaluation is going on "forever" that i have to abort it after some time.

FYI: i have following boundary conditions:

w[0]==0 | w[l]==0 | w''[0]==0 | w''[l]==0 | w''''[0]==q[0]/(EI0) | w''''[l]==q[l]/(EI0) | du'[0]==0 | du'[l]==0 

If i transfer the two differential equations to one DE 6th order i get a analytical solution. Why isn't that the case if i solve both equations simultaneously? Thank you in advance!

$\endgroup$
  • 2
    $\begingroup$ It is very unlikely that there will be a simple symbolic solution. Use NDSolve to get a numerical solution. (And of course, you have then to include you initial and boundary conditions in the call to NDSolve.) $\endgroup$ – Henrik Schumacher Feb 3 at 10:28
  • 1
    $\begingroup$ You have $3$ unknown functions $\Delta u(x), w(x), u(x)$ ( why such a very misleading notation?) and only two equations and so you cannot sove the system. I'm voting to close this question as impossible to answer without more detailed information. $\endgroup$ – Artes Feb 3 at 12:46
  • 1
    $\begingroup$ I would guess $q$ is a known function, but hard to say without any specification... Anyway, I would start by eliminating $w$ from the second equation using the first equation. That should give an linear second order ODE in $\Delta u,x$. $\endgroup$ – anderstood Feb 3 at 12:59
  • 2
    $\begingroup$ @anderstood You cannot solve the system if you don't know $q(x)$, that's all $\endgroup$ – Artes Feb 3 at 13:12
  • 3
    $\begingroup$ Also, please address issues in the question directly rather than in the comments; in particular, you should specify that q is a known function. I voted to reopen because this question seems clear enough. $\endgroup$ – anderstood Feb 4 at 8:42
2
$\begingroup$

The reopening of the question allows me to turn my comment into an answer and expand a bit:

You can solve for $\Delta u$ by eliminating $w$ in the second equation, using the first equation, without knowing $q$, but it gives a long expression:

  eq1 = du''[x] == d w'''[x] + K/EA du[x];
  eq2 = -EIinf w''''[x] + 2 d EA du'''[x] + q[x] == 0;
  sol = First@First@Solve[eq1, w'''[x]]
  eq2b = eq2 /. w''''[x] -> D[w'''[x] /. sol, x] // FullSimplify;
  dusol = DSolve[{eq2b, du'[0] == 0, du'[l] == 0}, du[x], x]
  dusol = Assuming[Reals, Simplify@dusol]

You can simplify the expression a bit if the variables are real (see last line above).

If you prescribe $q(x)=q_0\sin(\pi x/l)$ it becomes much much simpler:

  dusol = DSolve[{eq2b /. q[x] -> q0*Sin[Pi*x/l], du'[0] == 0, du'[l] == 0}, du[x], x]
  (* {{du[x] -> (-EIinf K l^2 π C[3] + 2 d^2 EA^2 π^3 C[3] - 
   EA EIinf π^3 C[3] - d EA l^3 q0 Cos[(π x)/l])/(π (-EIinf K l^2 + 
   2 d^2 EA^2 π^2 - EA EIinf π^2))}} *)

You can then inject the solution $\Delta u$ in the first equation and solve for $w$:

  eq1b = eq1 /. dusol /. du''[x] -> D[dusol[[1, 1, 2]], {x, 2}] // FullSimplify // First
  wsol = DSolve[{eq1b, w[0] == 0, w''[0] == 0}, w[x], x] // Simplify

  (* {{w[x] -> (π^4 (EIinf K l^2 - 2 d^2 EA^2 π^2 + 
   EA EIinf π^2) x (K x^2 C[3] - 6 d EA C[5]) - 
    6 d EA l^4 (K l^2 + EA π^2) q0 Sin[(π x)/l])/(
    12 d^3 EA^3 π^6 - 6 d EA EIinf π^4 (K l^2 + EA π^2))}}  *)

You should now be able to find C[3] and C[5] using the boundary conditions in l. By the way it seems you have two many boundary conditions (overdetermined problem).

| improve this answer | |
$\endgroup$
  • 1
    $\begingroup$ I want to thank you so much for your effort helping me to solve this problem! $\endgroup$ – WM_noob5 Feb 6 at 11:16

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.