$$ \int \frac{1}{\sqrt{1-2 x^3}} \, dx $$

Integrate[1/Sqrt[1 - 2 x^3], x]// FullSimplify

The result is very complex.

Then I want to differentiate it with the operator D.

% // D[#, x] & // FullSimplify

but I didn't get what I want.

How to add conditions to get origin formula?

Meanwhile, using Rubi can do it.

enter image description here

My Mathematica version is 11.3, and seems that in 12.0 , this question has been solved.

  • 2
    $\begingroup$ Mathematica's elliptic integral results tend to be more complicated than necessary. Nevertheless, using the results from this math.SE answer, you have the expression InverseJacobiCN[(2 Sqrt[3])/(1 + Sqrt[3] - x 2^(1/3)) - 1, (2 + Sqrt[3])/4]/(2^(1/3) 3^(1/4)) $\endgroup$ Jan 30, 2020 at 8:27

3 Answers 3


While the function x Hypergeometric2F1[1/3, 1/2, 4/3, 2 x^3] can be obtained by integration of the integrand $\frac{1}{\sqrt{1-2x^3}}$ in Mathematica 12 as observed by Bob Hanlon, it cannot be obtained in Mathematica 11.2 and earlier versions, even though D[x Hypergeometric2F1[1/3, 1/2, 4/3, 2 x^3],x] yields $\frac{1}{\sqrt{1-2x^3}}$ also in version 11.2. On the other hand J.M. observed that the integral can be expressed in terms of the elliptic integrals. This integral can be simply reformulated by the definition of the Weierstras elliptic function (see e.g. Integrate yields complex value, while after variable transformation the result is real. Bug?)

Recalling the linked post one can write (mind appropriate limits of integration and constants which can be complex in general): $$ \int \frac{1}{\sqrt{1-2 x^3}} \, dx = \int_{\infty}^{x} \frac{i \sqrt{2}}{\sqrt{4 t^3-2}}\,dt=i \sqrt{2}\; \wp^{-1}(x;0,2) $$ where $\wp$ in the Weierstrass elliptic function, while $\wp^{-1}$ is its inverse function implemented in the Wolfram Language as InverseWeierstrassP. This formula can be used only in appropriate regions of the real axis or the complex plane, as well as that given by x Hypergeometric2F1[1/3, 1/2, 4/3, 2 x^3] and the proper regions are different for the both expressions, signalizing that thay can be used in different cases. However as observed elsewhere (see e.g. answers to this question) the ellliptic integrals and functions where implemented in a suboptimal way at least until version 11.2 and and to demonstrate symbolically $$\frac{1}{\sqrt{1-2 x^3}}=i \sqrt{2}\; \frac{d}{dx}\wp^{-1}(x;0,2)$$ is difficult at least before version 12. Nonetheless we can do e.g.

FullSimplify[D[I Sqrt[2] InverseWeierstrassP[x, {0, 2}], x]]
(I Sqrt[2])/WeierstrassPPrime[InverseWeierstrassP[x, {0, 2}], {0, 2}]

i.e. acting with TraditionalForm yields $$\frac{1}{\sqrt{1-2 x^3}}=i \sqrt{2}\; \frac{d}{dx}\wp^{-1}(x;0,2)= \frac{i \sqrt{2}}{\wp'(\wp^{-1}(x;0,2);0,2)}=f(x)$$ we can also demonstrate this equality for numbers such that $1-2x^3>0$, e.g. define

f[x_] := (I Sqrt[2])/ WeierstrassPPrime[InverseWeierstrassP[x, {0, 2}], {0, 2}]

And @@ Table[
         FullSimplify[f[x] == 1/Sqrt[1 - 2 x^3]],
         {x, {2/3, 3/5, 13/20, 13/19, 5/7, 7/12, 15/23, 1/Sqrt[2],
              1/Sqrt[3], 1/Pi, 1/E, Sqrt[3]/Pi}}]

and plot the both functions, one is shifted by $1/20$ for a better presentation

Plot[{f[x], 1/Sqrt[1 - 2 x^3] - 1/20}, {x, -1, 1}, AxesOrigin -> {0, 0}]

enter image description here

This demonstrates certain flavours of equality of the both functions and I hope it makes clear what can be done in Mathematica on the symbolic level.

  • 2
    $\begingroup$ Alternatively, if you make the substitution $x=-\sqrt[3]{2}u$, you can obtain another (equivalent) Weierstrassian integral: -2^(1/3) InverseWeierstrassP[-(x/2^(1/3)), {0, -1}]. $\endgroup$ Jan 31, 2020 at 16:32
  • $\begingroup$ @J.M. Thanks for your remark. Indeed, this can be a helpful, however in our case I find my approach easier to handle. $\endgroup$
    – Artes
    Jan 31, 2020 at 17:05

Works well in version 12


(* "12.0.0 for Mac OS X x86 (64-bit) (April 7, 2019)" *)

int = Integrate[1/Sqrt[1 - 2 x^3], x]

(* x Hypergeometric2F1[1/3, 1/2, 4/3, 2 x^3] *)

The derivative returns the original expression

D[int, x]

(* 1/Sqrt[1 - 2 x^3] *)

Try the replacement u=x^3. Then dx=du/3u^2/3and

Integrate[1/3 u^(-2/3)/Sqrt[1 - 2 u], u] /. u -> x^3


(* (x^3)^(1/3) Hypergeometric2F1[1/3, 1/2, 4/3, 2 x^3]  *)

Have fun!

  • 1
    $\begingroup$ it gives out $\frac{B_{2 x^3}\left(\frac{1}{3},\frac{1}{2}\right)}{3 \sqrt[3]{2}}$ which is also very nice, thx. $\endgroup$ Feb 3, 2020 at 16:09

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.