2
$\begingroup$

Suppose that I have a complicated function F(a,x,y) and I want to plot the 2D region of (x,y) points such that F(a,x,y)=0 has a solution. How would that be possible in mathematica?

I would think that such a plot requires something on the lines of ImplicitRegion[Solve[F[a,x,y]==0,a],{x,y}] (of course, this code won't work).

EDIT: A simple example would be something like F[a,x,y]:=a^2 +x. Then F[a,x,y]==0 would only have a solution if x<=0 (assuming a,x,y are all Reals) and then I would like to plot the region x<=0 (with something like RegionPlot)

$\endgroup$
2
  • $\begingroup$ Thank you for adding an example. I'm afraid that I am still confused though. In your case of $F=a^2+x$, then $F=0$ is not satisfied by any value of $x<0$, but instead by exactly one value of $x$, i.e. $x=-a^2$, for each value of $a$. That's not a region, is it? Perhaps we really do need to see the complicated function. $\endgroup$
    – MarcoB
    Jan 20 '20 at 1:19
  • $\begingroup$ @MarcoB So if $x=-1,y=0$, then Solve[F[a,x,y]==0,a,Reals] returns a solution, namely $a=\pm 1$. Therefore, in my $(x,y)$ plot, the point $(x,y)=(-1,0)$ should be my colored region. If $x=1,y=0$, then Solve[F[a,x,y]==0,a,Reals] does not return a solution and thus in my $(x,y)$ plot, the point $(x,y)=(1,0)$ should NOT be my colored region. Repeat this thought process for all conceivable $(x,y)$ points and then we obtain a region $\endgroup$ Jan 20 '20 at 1:24
1
$\begingroup$

Get a fast impression e.g. for a^2 + x - y^2 == 0 with

ContourPlot3D[a^2 + x - y^2 == 0, {x, -3, 3}, {y, -3, 3}, {a, -4, 4}, 
  ViewPoint -> {0, 0, Infinity}, AxesLabel -> {x, y}, 
  MeshFunctions -> Function[{x, y, a}, a], Mesh -> {Range[-3, 3]}]

enter image description here

$\endgroup$
1
$\begingroup$
reg = Resolve[Exists[a, x^2 + a^2 - y == 0], Reals] //
  ImplicitRegion[#, {x, y}] &
(*  ImplicitRegion[x^2 - y <= 0, {x, y}]  *)

RegionPlot[reg]

enter image description here

Of course, transcendental equations are not always possible for solvers to solve. And high-degree equations can be a challenge, too.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.