13
$\begingroup$

How to solve this matrix equation

Solve[MatrixRank[( {
     {1, x, 3},
     {2, 4, 5},
     {2, 4, x}
    } )] == 2, x, Reals]
$\endgroup$
10
$\begingroup$

A not so good answer

Cases[Table[{x, MatrixRank[({{1, x, 3}, {2, 4, 5}, {2, 4, x}})]}, {x, -10, 10, 1/10}], {_, 2}]

gives out

{{2, 2}, {5, 2}}

So answer is 2 or 5.

$\endgroup$
18
$\begingroup$
mat = ({{1, x, 3}, {2, 4, 5}, {2, 4, x}});
Select[MatrixRank[mat /. #] == 2 &][Solve[Det[mat] == 0, x, Reals]]

{{x -> 2}, {x -> 5}}

$\endgroup$
11
$\begingroup$

Solutions force exactly one eigenvalue to be zero. So we solve for the condition that an eigenvalue vanish, and check that rank is two.

mat = {{1, x, 3}, {2, 4, 5}, {2, 4, x}};
candidateSols = Flatten[Map[Solve[# == 0, x] &, Eigenvalues[(mat)]]]

(* Out[997]= {x -> 2, x -> 5} *)

Both pass the test:

Map[MatrixRank[mat /. #] &, candidateSols]

(* Out[995]= {2, 2} *)
$\endgroup$
  • 1
    $\begingroup$ I should have read the @kglr answer more carefully. It avoids, or at least postpones, working in an algebraic extension. $\endgroup$ – Daniel Lichtblau Jan 19 at 17:34
4
$\begingroup$

Here is an indirect route, which has the advantage of postponing operations like MatrixRank[] until the end.

Consider the identity

$$\begin{pmatrix}1&x&3\\2&4&5\\2&4&x\end{pmatrix}=\begin{pmatrix}1&0&3\\2&4&5\\2&4&0\end{pmatrix}+\begin{pmatrix}x&0\\0&0\\0&x\end{pmatrix}\begin{pmatrix}0&1&0\\0&0&1\end{pmatrix}$$

A condition for this matrix to be invertible (cf. the Sherman-Morrison-Woodbury formula) is that the capacitance matrix

$$\begin{pmatrix}1&0\\0&1\end{pmatrix}+\begin{pmatrix}0&1&0\\0&0&1\end{pmatrix}\begin{pmatrix}1&0&3\\2&4&5\\2&4&0\end{pmatrix}^{(-1)}\begin{pmatrix}x&0\\0&0\\0&x\end{pmatrix}=\begin{pmatrix}1-\frac{x}{2}&-\frac{x}{20}\\0&1-\frac{x}{5}\end{pmatrix}$$

be nonsingular.

Thus,

Solve[Det[IdentityMatrix[2] +
          {{0, 1, 0}, {0, 0, 1}}.LinearSolve[{{1, 0, 3}, {2, 4, 5}, {2, 4, 0}},
                                             {{x, 0}, {0, 0}, {0, x}}]] == 0, x]
   {{x -> 2}, {x -> 5}}

Check:

MatrixRank /@ ({{1, x, 3}, {2, 4, 5}, {2, 4, x}} /. %)
   {2, 2}
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.