7
$\begingroup$

Let $ABC$ be a triangle from plane such that we define three points $I$, $J$ ,$G$ satisfying respectively the following equations: $$2 \vec{IA}+\vec{IB} =\vec{0}$$ $$\vec{JB}-2\vec{JC} =\vec{0}$$ $$2\vec{GA}+\vec{GB} -2 \vec{GC}=\vec{0}$$

How I can plot that system of vectorial equation in Cartesian coordinates with respect to triangle $ABC$? By hand, I obtained $G$ as a point of interesction between $(CI)$ and $(AG)$ such that $(AC)$ and $(BG)$ are parallel.

$\endgroup$
5
$\begingroup$
Clear[a, b, c, i, j, g]
SeedRandom[1542]

Set up your equations and solve them:

equations = {
 2 (Array[i, 2] - Array[a, 2]) + (Array[i, 2] - Array[b, 2]) == 0,
   (Array[j, 2] - Array[b, 2]) - 2 (Array[j, 2] - Array[c, 2]) == 0,
 2 (Array[g, 2] - Array[a, 2]) + (Array[g, 2] - Array[b, 2]) - 2 (Array[g, 2] - Array[c, 2]) == 0
} // Simplify;

solutions = ToRules@Reduce[equations, Evaluate@Flatten@{Array[#, 2] & /@ {a, b, c, i, j, g}}];

Choose some random values for $A,B,C$ and calculate the corresponding $I,J,G$ using the rules obtained above:

Evaluate[Array[#, 2] & /@ {a, b, c}] = RandomReal[1, {3, 2}];
Array[#, 2] & /@ {i, j, g} /. solutions;

Create a graphical representation:

Show[
  (* plot points *)
  ListPlot[
    MapThread[
      {Labeled[Array[#1, 2], Style[#2, 16]]} &,
      {
        {a, b, c, i, j, g},
        {"a", "b", "c", "i", "j", "g"}
      }
    ] /. solutions,
    PlotStyle -> PointSize[0.02]
  ],

  (* add triangle and lines *)
  Graphics[{
    EdgeForm[{Thick, Black}], FaceForm[None],
    Triangle[Array[#, 2] & /@ {a, b, c}],
    {
      (*IA, IB*)
      Red,  Line[Array[#, 2] & /@ {i, a}], 
      Blue, Line[Array[#, 2] & /@ {i, b}],

      Purple,(*JB, JC*)
      Line[Array[#, 2] & /@ {j, b}], Line[Array[#, 2] & /@ {j, c}],

      Darker@Green,(*GA, GB, GC*)
      Line[Array[#, 2] & /@ {g, a}], 
      Line[Array[#, 2] & /@ {g, b}], 
      Line[Array[#, 2] & /@ {g, c}]
    } /. solutions
  }],
  PlotRange -> All
]

graphics with all geometric elements

$\endgroup$
5
$\begingroup$

Use RandomInstance and GeometricScene to draw the picture:

ri = RandomInstance[
  GeometricScene[
   {
    {a, b, c, i, j, g},
    {a1, a2, b1, b2, c1, c2, i1, i2, j1, j2, g1, g2}
    },
   {
    a == {a1, a2}, b == {b1, b2}, c == {c1, c2}, i == {i1, i2}, 
    j == {j1, j2}, g == {g1, g2},
    Triangle[{a, b, c}],
    2*({a1, a2} - {i1, i2}) + ({b1, b2} - {i1, i2}) == {0, 0},
    ({b1, b2} - {j1, j2}) - 2*({c1, c2} - {j1, j2}) == {0, 0},
    2*({a1, a2} - {g1, g2}) + ({b1, b2} - {g1, g2}) - 
      2*({c1, c2} - {g1, g2}) == {0, 0}
    }
   ]
  ]

enter image description here

Extract the point coordinates:

ri["Points"]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.