I want to integrate the function below analytically, so that later on I can use the result for numerical calculations. But it seems Mathematica can not handle it the way I express it. However, if I change the argument of the Bessel function from $s^{1/2}$ to $s$, then Mathematica handles it easily.

I tried to evaluate

int1 = 
  Integrate[BesselK[1, s^(1/2)/T], {s, 4 mX^2, Infinity}, 
    GenerateConditions -> False]

and got this output:

Integrate[BesselK[1, Sqrt[s]/T], {s, 4 mX^2, Infinity}, 
  GenerateConditions -> False]

But after changing the argument of the Bessel function from $s^{1/2 }$ to $s$:

Integrate[BesselK[1, s/T], {s, 4 mX^2, Infinity}, GenerateConditions -> False]

I got this output:

BesselK[0, (4 Sqrt[1/T^2])/Sqrt[1/mX^4]]/Sqrt[1/T^2]

which I can further use for numerical evaluation.

I need some suggestions.

  • 4
    $\begingroup$ The first and the second integral are not equivalent. MA can compute the first integral without the limits in terms of the Meijer function. You can substitute limits manually. $\endgroup$
    – yarchik
    Commented Jan 8, 2020 at 21:03

1 Answer 1


The integration limit at $\infty$ causes problems. One idea is to integrate over the range from 0 to $\infty$, and then subtract off the integral from 0 to 4 mX^2:

i0 = Integrate[BesselK[1, Sqrt[s]/T], {s, 0, Infinity}, Assumptions->T>0]
i[a_] = Integrate[BesselK[1, Sqrt[s]/T], {s, 0, a}, Assumptions->T>0 && a>0]

π T^2

2 T^2 MeijerG[{{1}, {}}, {{1/2, 3/2}, {0}}, a/(4 T^2)]

Then, the desired integral is:

int[T_, mX_] = i0 - i[4 mX^2]

π T^2 - 2 T^2 MeijerG[{{1}, {}}, {{1/2, 3/2}, {0}}, mX^2/T^2]

As a check, here's a function to integrate numerically:

nint[T_, mX_] := NIntegrate[BesselK[1, Sqrt[s]/T], {s, 4 mX^2, Infinity}]


int[10, 2] //N
nint[10, 2]



  • $\begingroup$ The limit at $\infty$ appears to approach $T^2\pi$ by numerically checking large $s$ for several values of $T$. $\endgroup$
    – Bill Watts
    Commented Jan 9, 2020 at 8:09

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.