Quick way to preview and tweak styles?

Question

I find the old stylesheet UI clunky and hard to use:

FrontEndExecute @ FrontEndToken @ "EditStyleDefinitions"

There's also the clunky style previewer as well:

Without using the above, I'd like to programmatically quickly tweak and preview styled expressions and definitions for named styles. For example, let's try copying "Entity" and renaming it "MyRoundedFrameStyle" giving it different colors and frame properties:

CellPrint @ Cell[BoxData[
    TemplateBox[{"\"United States\"", , , "country"}, "Entity"]], 
  "Input"]

What I've tried:

Here's some code to get started:

DynamicModule[{x = ""}, TextGrid[{{"Input", "Output"}, 
    {InputField[Dynamic[x], String, ContinuousAction -> True],           
    Dynamic[DisplayForm[Check[DisplayForm@ToExpression[x], "-"]]]}}, 
   Alignment -> Center, Dividers -> All]]

Obviously, it doesn't work well:

Notes:

• Being able to do this inline and programmatically within a notebook would "be best" ;)
• I haven't seen any ResourceFunction that could help here...
• Perhaps there are some undocumented symbols that let one ergonomically copy-and-tweak (predefined cell or box) styles for quick reuse?
• If nothing like this exists, StylePlayground would be a good name!

Answer 1

Here's my preferred way to do this. First we'll make some template:

Options[createPreviewNotebookTemplate] =
    {
       "Styles" -> {
             "Title", "Subtitle", "Chapter",
             "Section", "Subsection", "Subsubsection",
             "Text", "Code", "Input", "Output",
             "Item", "ItemNumbered", "ItemParagraph",
             "Subitem", "SubitemNumbered", "SubitemParagraph",
             "InlineFormula", "DisplayFormula", "Program"
           },
       "StyleContentMap" -> {
           "Code" -> BoxData, 
           "Input" -> BoxData, 
           "Output" -> BoxData,
           _ -> Identity
           }
       };
createPreviewNotebookTemplate[ops : OptionsPattern[]] :=

 With[{map = OptionValue["StyleContentMap"]},
      Notebook[
         Map[Cell[(# /. map)[#], #] &, OptionValue["Styles"]]
         ]
      ]

nb = CreateDocument@createPreviewNotebookTemplate[]

Then you can load a package I've had on my GitHub for a while and play with the styling:

Get["https://raw.githubusercontent.com/b3m2a1/mathematica-tools/master/StylesheetEdit.wl"]

(*StyleSheetNew[nb, "Title"]*) (* you only want this one time, before you start adding edits *)
StyleSheetEdit[nb, "Title",
 {
   FontColor -> Pink
  }
 ]

(*StyleSheetNew[nb, "Notebook"]*)
StyleSheetEdit[nb, "Notebook",
 {
   Background -> GrayLevel[.9]
  }
 ]

You can also revert edits:

StyleSheetDelete[nb, "Notebook"]

This is affecting the actual stylesheet notebook that nb uses, not continuously writing to StyleDefinitions. If nb were a stylesheet notebook in and of itself the changes will be applied to all notebooks that depend on that sheet.

E.g. we can get the sheet for a given notebook via:

defaultSheet =
 Lookup[NotebookInformation[EvaluationNotebook[]], "StyleDefinitions"][[1]]

Then when I do:

StyleSheetEdit[defaultSheet, "Notebook",
 {
   Background -> GrayLevel[.9]
  }
 ]

every notebook that uses "Default.nb" will get a gray background.

We can revert that without deleting the cell by

StyleSheetEdit[defaultSheet, "Notebook",
 {
   Background -> Inherited
  }
 ]