1
$\begingroup$

Let us have a expression:

-((-2 + 13 e - 12 e^2)/(
  6 (-e + 2 e^2))) + ((1 - I Sqrt[3]) (-4 + 4 e - e^2))/(
 6 2^(2/3) (-e + 2 e^2) (16 - 24 e - 420 e^2 + 1294 e^3 - 1296 e^4 + 
    432 e^5 + Sqrt[
    4 (-4 + 4 e - e^2)^3 + (16 - 24 e - 420 e^2 + 1294 e^3 - 
       1296 e^4 + 432 e^5)^2])^(
  1/3)) - ((1 + I Sqrt[3]) (16 - 24 e - 420 e^2 + 1294 e^3 - 
    1296 e^4 + 432 e^5 + Sqrt[
    4 (-4 + 4 e - e^2)^3 + (16 - 24 e - 420 e^2 + 1294 e^3 - 
       1296 e^4 + 432 e^5)^2])^(1/3))/(12 2^(1/3) (-e + 2 e^2))

I am interested only in real part on interval $e \in (0,0.1)$.

There is also an observation that the imaginary part of that interval is $0i$ (but I believe this observation is not useful).

I am still not experienced Mathematica (nor math :) ) user but I believe I might find an expression which is "more convenient" -- I would like to use a result in a presentation.

$\endgroup$
2
$\begingroup$

(Update: Re was unhelpful here; removing it.)

I am not sure how helpful this is, but if we start with a qualified FullSimplify:

expr = (* your expression here *)

simp = FullSimplify[expr, 0 <= e <= 1/10]
(1/(24 e (-1 + 2 e)))(8 - 52 e + 48 e^2 + (
  2 I (I + Sqrt[3]) (-2 + e)^2)/(8 - 12 e - 210 e^2 + 647 e^3 - 648 e^4 + 216 e^5 + 
    12 Sqrt[3] (1 - 2 e) e Sqrt[(-1 + e)^3 (8 + e (20 + 27 (-2 + e) e))])^(1/3) - 
  2 (1 + I Sqrt[3]) (8 - 12 e - 210 e^2 + 647 e^3 - 648 e^4 + 216 e^5 + 
     12 Sqrt[3] (1 - 2 e) e Sqrt[(-1 + e)^3 (8 + e (20 + 27 (-2 + e) e))])^(1/3))

Then pluck out the repeated part and name it p we can write:

p = (8 - 12 e - 210 e^2 + 647 e^3 - 648 e^4 + 216 e^5 + 
    12 Sqrt[3] (1 - 2 e) e Sqrt[(-1 + e)^3 (8 + e (20 + 27 (-2 + e) e))])^(1/3);

new = (1/(24 e (-1 + 2 e)))(8 - 52 e + 48 e^2 + (2 I (I + Sqrt[3]) (-2 + e)^2)/p - 
  2 (1 + I Sqrt[3]) p);

new == simp
True
$\endgroup$
  • $\begingroup$ This is probably the best solution. Consider as an answer. $\endgroup$ – hardcheese Jan 7 at 10:03
  • $\begingroup$ @hardcheese If someone posts a better answer you can change the Accept. I realized that my use of Re didn't actually help anything so I removed it. $\endgroup$ – Mr.Wizard Jan 7 at 10:15
1
$\begingroup$

Why not apply ComplexExpand to get an expression totaly free of imginary unit I ?

ceRe = ComplexExpand[Re[expr], TargetFunctions -> {Re, Im}] 
// FullSimplify[#, 0 <= e <= 1/10] &

(*   (1/(6 e (-1 + 2 e)))(2 + e (-13 + 12 e) + (-2 + e) 
Cos[1/3 ArcTan[8 + e (-12 + e (-210 + e (647 + 216 (-3 + e) e))), 
  12 Sqrt[3] (1 - 2 e) (1 - e)^(3/2) e Sqrt[
   8 + e (20 + 27 (-2 + e) e)]]] - 
Sqrt[3] (-2 + e) Sin[
1/3 ArcTan[8 + e (-12 + e (-210 + e (647 + 216 (-3 + e) e))), 
  12 Sqrt[3] (1 - 2 e) (1 - e)^(3/2) e Sqrt[
   8 + e (20 + 27 (-2 + e) e)]]])   *)

Imaginary part there is zero.

ceIm = ComplexExpand[Im[expr], TargetFunctions -> {Re, Im}] 
// FullSimplify[#, 0 <= e <= 1/10] &

(*   0   *)
$\endgroup$
0
$\begingroup$

Not an answer because I am not sure exactly what the OP wants as the output. However :

expr = -((-2 + 13 e - 12 e^2)/(6 (-e + 2 e^2))) + ((1 - 
        I Sqrt[3]) (-4 + 4 e - e^2))/(6 2^(2/3) (-e + 
        2 e^2) (16 - 24 e - 420 e^2 + 1294 e^3 - 1296 e^4 + 432 e^5 + 
         Sqrt[4 (-4 + 4 e - e^2)^3 + (16 - 24 e - 420 e^2 + 
              1294 e^3 - 1296 e^4 + 432 e^5)^2])^(1/3)) - ((1 + 
        I Sqrt[3]) (16 - 24 e - 420 e^2 + 1294 e^3 - 1296 e^4 + 
         432 e^5 + 
         Sqrt[4 (-4 + 4 e - e^2)^3 + (16 - 24 e - 420 e^2 + 
              1294 e^3 - 1296 e^4 + 432 e^5)^2])^(1/3))/(12 2^(1/
         3) (-e + 2 e^2));

Table[expr, {e, 0, 0.1, 0.01}]

   (* {Indeterminate, 0.585178 + 0. I, 0.584564 - 5.32907*10^-15 I, 
     0.583947 + 0. I, 0.583325 + 0. I, 0.582698 - 8.88178*10^-16 I, 
     0.582067 + 0. I, 0.581431 + 0. I, 0.58079 + 2.66454*10^-15 I, 
     0.580144 + 0. I, 0.579494 - 8.88178*10^-16 I} *)

Chop[%]

{Indeterminate, 0.585178, 0.584564, 0.583947, 0.583325, \
0.582698, 0.582067, 0.581431, 0.58079, 0.580144, 0.579494}

We can see that all the Imaginary parts are very tiny and are chopped off.

@hardcheese : Is this what you wanted ?

$\endgroup$
  • $\begingroup$ I want to obtain also an expression but over $R$, not $C$. I believe that expression could be much simpler and better for my talk. I am not sure if it is mathematically possible through. I have already obtained results which are not important right now. I care only about aesthetic... $\endgroup$ – hardcheese Jan 7 at 9:21
  • $\begingroup$ Background: This expression is a result of research and the product of many steps. It gives us correct results but as you can see, the form of the expression is not convenient for presentations, talks or for papers. It would be extremely useful if I find a simpler form (which I believed, removing the imaginary part is the right way..) $\endgroup$ – hardcheese Jan 7 at 9:37

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.