4
$\begingroup$

I have an inequality that defines a paraboloid. I would like to calculate the volume of the intersection of this paraboloid and a cylinder of radius R.

ff[a_, d_, x_, y_, z_] := 
  16 a^2 y^4 + a y^3 (-32 a^2 - 8 d^2 - 8 x^2 - 8 z^2) + 
  a y (32 a^2 d^2 + 8 d^4 - 8 a^2 x^2 + 2 d^2 x^2 - 10 x^4 - 
  8 a^2 z^2 + 2 d^2 z^2 - 20 x^2 z^2 - 10 z^4) + 
  y^2 (16 a^4 - 8 a^2 d^2 + d^4 + 32 a^2 x^2 - 2 d^2 x^2 + x^4 + 
  32 a^2 z^2 - 2 d^2 z^2 + 2 x^2 z^2 + z^4) - (16 a^4 d^2 + 
  8 a^2 d^4 + d^6 + 20 a^2 d^2 x^2 - 3 d^4 x^2 - a^2 x^4 + 
  3 d^2 x^4 - x^6 + 20 a^2 d^2 z^2 - 3 d^4 z^2 - 2 a^2 x^2 z^2 + 
  6 d^2 x^2 z^2 - 3 x^4 z^2 - a^2 z^4 + 3 d^2 z^4 - 3 x^2 z^4 - z^6);

Vol[R_, a_] := 
  Integrate[
    Boole[ff[a, d, x, y, z] <= 0 && x^2 + z^2 <= R^2], 
    {x, -R, R}, {y, -20, 20}, {z, -R, R}];

My problem is that Mathematica does not yield a result. Is there any way to do it?.

$\endgroup$
6
$\begingroup$
Clear["Global`*"]

ff[a_, d_, x_, y_, z_] := 
  16 a^2 y^4 + a y^3 (-32 a^2 - 8 d^2 - 8 x^2 - 8 z^2) + 
   a y (32 a^2 d^2 + 8 d^4 - 8 a^2 x^2 + 2 d^2 x^2 - 10 x^4 - 
      8 a^2 z^2 + 2 d^2 z^2 - 20 x^2 z^2 - 10 z^4) + 
   y^2 (16 a^4 - 8 a^2 d^2 + d^4 + 32 a^2 x^2 - 2 d^2 x^2 + x^4 + 
      32 a^2 z^2 - 2 d^2 z^2 + 2 x^2 z^2 + z^4) - (16 a^4 d^2 + 
     8 a^2 d^4 + d^6 + 20 a^2 d^2 x^2 - 3 d^4 x^2 - a^2 x^4 + 
     3 d^2 x^4 - x^6 + 20 a^2 d^2 z^2 - 3 d^4 z^2 - 2 a^2 x^2 z^2 + 
     6 d^2 x^2 z^2 - 3 x^4 z^2 - a^2 z^4 + 3 d^2 z^4 - 3 x^2 z^4 - 
     z^6);

Vol[R_?Positive, a_?NumericQ, d_?NumericQ] := 
  NIntegrate[
   Boole[ff[a, d, x, y, z] <= 0 && x^2 + z^2 <= R^2], {x, -R, 
    R}, {y, -20, 20}, {z, -R, R}];

Vol[10, 1, 1]

(* 1599.87 *)

reg[R_?Positive, a_?NumericQ, d_?NumericQ] :=
 ImplicitRegion[
  ff[a, d, x, y, z] <= 0 && 
   x^2 + z^2 <= R^2 && -R <= x <= R && -20 <= y <= 20 && -R <= z <= 
    R, {x, y, z}]

Volume[reg[10, 1, 1]]

(* 1599.87 *)
$\endgroup$
  • $\begingroup$ thanks, but Is it possible to find an analytical expression? $\endgroup$ – F.Mark Jan 7 at 2:17
  • 1
    $\begingroup$ Without using numeric values, determining when ff[a, d, x, y, z] <= 0 would seem unlikely. $\endgroup$ – Bob Hanlon Jan 7 at 2:58
  • $\begingroup$ thanks so mucho $\endgroup$ – F.Mark Jan 8 at 2:13
  • $\begingroup$ @F.Mark perhaps you could either use this numerical procedure and plot some dependencies? Or you could try to nondimensionalize your function to use less variables? $\endgroup$ – CA Trevillian Jan 11 at 23:15

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.