BarChart Labels for two lists

Question

a quick question:

I am trying to label a BarChart that consists of two lists (groups). The label should keep going on with the Label list (so ddd, eee, fff) and not repeat itself (and start from aaa, bbb...) after the first group ends (see picture underneath)

A simplified code:

  BarChart[{{1, 2, 3}, {4, 5, 6}}, 
 ChartLabels -> {aaa, bbb, ccc, ddd, eee, fff}, 
 ChartStyle -> {{Red, Green}, None}]

With the dataset:

Answer 1

data = {{1, 2, 3}, {4, 5, 6}};
labels = {aaa, bbb, ccc, ddd, eee, fff};
labeleddata = TakeList[MapIndexed[Labeled[#, labels[[#2[[1]]]]] &, 
  Flatten @ data], Length /@ data]

BarChart[labeleddata, ChartStyle -> {{Red, Green}, None}]

You can also define labeleddata as

labeleddata = MapThread[Labeled] /@ Transpose[{data, TakeList[labels, Length /@ data]}]

Update: An alternative approach using the option LabelingFunction:

ClearAll[labelingF]
labelingF[data_, labels_] := 
 Association[
  Flatten@MapIndexed[#2 -> # &, TakeList[labels, Length /@ data], {2}]]

Examples:

data = {{1, 2, 3}, {4, 5, 6, 7, 8}};
labels = {aaa, bbb, ccc, ddd, eee, fff, ggg, hhh};

BarChart[data, ChartStyle -> {{Red, Green}, None}, 
 LabelingFunction -> (Placed[Rotate[#, 60 Degree] &@labelingF[data, labels]@#2, Below] &)]

Use data = {{1, 2, 3}, {4, 5, 6}, {7, 8}} and ChartStyle -> {{Red, Green, Orange}, None} to get