How to make the boundary of a 3D region smooth?

Question

I want to draw this region,but the surface is rough.I tried to find options to improve the surface but failed.

Region[RegionIntersection[Cylinder[{{0, 0, -2}, {0, 0, 2}}],
  Cylinder[{{0, -2, 0}, {0, 2, 0}}], 
  Cylinder[{{-2, 0, 0}, {2, 0, 0}}]]]

which gives

besides, PlotPoints -> 200 seems have no place to put.

Answer 1

Sometimes, it is easier to discretize before intersecting.

BoundaryDiscretizeRegion@RegionIntersection[
  Map[
   BoundaryDiscretizeRegion[#, 
     MaxCellMeasure -> (1 -> 0.05)] &, 
     {Cylinder[{{0, 0, -2}, {0, 0, 2}}], Cylinder[{{0, -2, 0}, {0, 2, 0}}], 
    Cylinder[{{-2, 0, 0}, {2, 0, 0}}]}
   ]
  ]

Answer 2

Using OpenCascadeLink from version 12.1 makes this easier and better quality:

Needs["NDSolve`FEM`"]
rr = RegionIntersection[Cylinder[{{0, 0, -2}, {0, 0, 2}}], 
   Cylinder[{{0, -2, 0}, {0, 2, 0}}], 
   Cylinder[{{-2, 0, 0}, {2, 0, 0}}]];
bmesh = ToBoundaryMesh[rr, 
   "BoundaryMeshGenerator" -> {"OpenCascade", 
     "ShapeSurfaceMeshOptions" -> {"LinearDeflection" -> 0.00125}}];
bmesh["Wireframe"[
  "MeshElementStyle" -> Directive[FaceForm[Green], EdgeForm[]]]]

Answer 3

ri = RegionIntersection[Cylinder[{{0, 0, -2}, {0, 0, 2}}], 
   Cylinder[{{0, -2, 0}, {0, 2, 0}}], Cylinder[{{-2, 0, 0}, {2, 0, 0}}]];

You can use PlotPoints as a suboption for Method options:

DiscretizeRegion[ri, 
 Method -> {"DualMarchingCubes", PlotPoints -> 150}]

Answer 4

In order to completeness,here we provide another ways to do this. Thanks @xzczd suggestion。

Related How to graph a solid common to multiple functions

• MeshFunctions

Clear[f, g, h, fgh, ghf, hfg];
SetOptions[ContourPlot3D, PlotPoints -> 80, MaxRecursion -> 4, 
  Mesh -> {{0}, {0}, {0}}, BoundaryStyle -> None, Boxed -> False, 
  Axes -> False];
f = {x, y, z} |-> x^2 + y^2 - 1;
g = {x, y, z} |-> y^2 + z^2 - 1;
h = {x, y, z} |-> z^2 + x^2 - 1;
fgh = ContourPlot3D[
   f[x, y, z] == 0, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, 
   MeshFunctions -> {g, h}, 
   MeshShading -> {{Red, None}, {None, None}}, MeshStyle -> None];
ghf = ContourPlot3D[
   g[x, y, z] == 0, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, 
   MeshFunctions -> {h, f}, 
   MeshShading -> {{Yellow, None}, {None, None}}, MeshStyle -> None];
hfg = ContourPlot3D[
   h[x, y, z] == 0, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, 
   MeshFunctions -> {f, g}, 
   MeshShading -> {{Cyan, None}, {None, None}}, MeshStyle -> None];
Show[fgh, ghf, hfg]

• CSGRegion

CSGRegion["Intersection", {Cylinder[{{0, 0, -2}, {0, 0, 2}}], 
  Cylinder[{{0, -2, 0}, {0, 2, 0}}], 
  Cylinder[{{-2, 0, 0}, {2, 0, 0}}]}, BaseStyle -> Darker@Cyan]

• OpenCascadeLink` (Thanks @user21)

Needs["OpenCascadeLink`"];
shape = OpenCascadeShape[
   RegionIntersection[Cylinder[{{0, 0, -1}, {0, 0, 1}}], 
    Cylinder[{{0, -1, 0}, {0, 1, 0}}], 
    Cylinder[{{-1, 0, 0}, {1, 0, 0}}]]];
bm = OpenCascadeShapeSurfaceMeshToBoundaryMesh[shape, 
    "ShapeSurfaceMeshOptions" -> {"AngularDeflection" -> .01}] // 
   BoundaryMeshRegion;
RegionPlot3D[bm, ColorFunction -> "Rainbow", Boxed -> False]

Or

Needs["OpenCascadeLink`"];
reg1 = Cylinder[{{0, 0, -2}, {0, 0, 2}}];
reg2 = Cylinder[{{0, -2, 0}, {0, 2, 0}}];
reg3 = Cylinder[{{-2, 0, 0}, {2, 0, 0}}];
shape1 = OpenCascadeShape[reg1];
shape2 = OpenCascadeShape[reg2];
shape3 = OpenCascadeShape[reg3];
bm = OpenCascadeShapeSurfaceMeshToBoundaryMesh[
    OpenCascadeShapeIntersection[shape1, shape2, shape3], 
    "ShapeSurfaceMeshOptions" -> {"AngularDeflection" -> .01}] // 
   BoundaryMeshRegion;
bm // Volume;
RegionPlot3D[bm, ColorFunction -> "Rainbow", Boxed -> False]

Answer 5

Yet another way to discretize the Steinmetz solid is to directly derive the required inequalities using RegionMember[]:

ineq = Simplify[RegionMember[RegionIntersection[Cylinder[{{0, 0, -2}, {0, 0, 2}}], 
                                                Cylinder[{{0, -2, 0}, {0, 2, 0}}], 
                                                Cylinder[{{-2, 0, 0}, {2, 0, 0}}]],
                             {x, y, z}], {x, y, z} ∈ Reals]
   -2 <= z <= 2 && x^2 + y^2 <= 1 && -2 <= y <= 2 && x^2 + z^2 <= 1 &&
   -2 <= x <= 2 && y^2 + z^2 <= 1

which can then be fed to ImplicitRegion[]:

reg = ImplicitRegion[ineq, {x, y, z}];
BoundaryDiscretizeRegion[reg, MaxCellMeasure -> {"Length" -> 0.02}]

Answer 6

reg = Polygon[
  Join[#, Reverse[#.DiagonalMatrix[{1, -1}]]] &@
   Table[{x, Min[AngleVector[Mod[x, Pi/2]]]}, {x, 0., 2 Pi, 2 Pi/(25*8)}]]

ParametricPlot3D[{{Cos[t], Sin[t], h}, {h, Cos[t], Sin[t]}, {Cos[t], h, Sin[t]}}, 
  Element[{t, h}, reg], ImageSize -> 600] // AbsoluteTiming

For version 13.x, you need to use Visualization`Core`ParametricPlot3D instead of ParametricPlot3D.
Related link, the-last-syntax-of-parametricplot3d-seems-broken-in-v13-x

Answer 7

Now I know how to solve this:

besides, PlotPoints -> 200 seems to have no place to put.

RegionIntersection[
    Cylinder[{{0, 0, -2}, {0, 0, 2}}],
    Cylinder[{{0, -2, 0}, {0, 2, 0}}], 
    Cylinder[{{-2, 0, 0}, {2, 0, 0}}]] //
RegionPlot3D[#, PlotPoints->80]&