How stretch curly brace on multi-line text?

Question

What's the cell option (or other technique) to use to stretch the curly brace that one typically uses in traditional math to group several displayed equations? Like this:

And is there any better way of getting the vertical alignments of the equations that simply inserting a 3-column table?

Answer 1

Here is one of my personal examples:

How I did it:

• Ctrl 9 (inline cell); doesn't work on/as the first case/letter of a Text cell (needs at leas a space)
• esc pw esc
• copy paste inside the pw element the output of something like Grid[{{a}, {b}, {c}}, Alignment -> Left]
• substitute the content a, b, c with your content

Then you can reuse it... (I have an entire book written with these structures)

Your example, with the same technique:

You can obviously tweak it a lot with Spacings, ItemSize, Style, etc

And you can even go to the extreme of:

• Ctrl 9
• esc pw esc
• write inside the pw element Grid[{{HoldForm[x-1=t]},{HoldForm[y=1-t^2]}},Alignment->"="]
• select the Grid[...], and choose evaluate in place (from the context menu)

...and editing it holds the alignment specification to the "=" sign!

And for the slightly extra extension of the brackets:

It is also possible to simulate an align to different characters, although the only way I found is a little messier. There are invisible characters available in Mathematica. Be careful because they are... well... invisible. This means that you can mess things if they end up in the middle of computations... I'm going to demonstrate the technique with the esc am esc (aka \[AlignmentMarker]).

Another problem with this technique is that, since there is an invisible thing in the middle of the expression, the parser complains about it. So, I entered everything as strings (there's probably a better way of avoiding it). But, entering everything as string, brakes special characters formating during evaluation in place... But everything ends up working after editing it. Here is a way of doing:

• Ctrl 9
• esc pw esc
• write inside the pw element Column[{Null,Grid[{{"test\[AlignmentMarker]=b"},{"bigger test\[AlignmentMarker]>b"}},Alignment->"\[AlignmentMarker]"],Null},ItemSize->{Automatic,{0.1,{02.},0.1}}]
• select the Column[...], and choose evaluate in place (from the context menu)

• edit to your needs (including the erasing of the "'s, but, while editing, don't erase your markers!)

Answer 2

I would use a formatting function like this:

Format[bracket[obj_]] :=
  Style[DisplayForm @ RowBox[{"{", obj}], SpanMaxSize -> Infinity]

Or with MakeBoxes, which may be preferable:

MakeBoxes[bracket[obj_], fmt_] :=
  StyleBox[RowBox[{"{", obj ~ToBoxes~ fmt}], SpanMaxSize -> Infinity]

(You don't need both definitions at the same time.)

Then it will left-bracket whatever expression you give it:

Grid[Binomial ~Array~ {5, 5}] // bracket

{"one", "two", "three"} // Column // bracket

Plot[Sinc[x], {x, 0, 10}] // bracket

---

As a separate answer to the second part of your question you can use the Alignment option.
This works with both Strings and held expressions:

Column[{"x = 1+t", "two = 1-t^2", "three = 1+t^3"}, Alignment -> "="]

Column[
 HoldForm /@ Unevaluated@{x = 1 + t, two = 1 - t^2, three = 1 + t^3}, 
 Alignment -> "="
]

Combined with bracket:

% // bracket

Answer 3

For convenient typesetting, I would use a palette in this case:

CreatePalette[
 Column[{
   "Extensible Brackets",
   Style[
    Grid[
     Join[
      Partition[
       Map[PasteButton[
          Style[RawBoxes@
            RowBox@Insert[#, "\[SelectionPlaceholder]", 2], 
           SpanMaxSize -> Infinity]] &, 
        Most@Tuples[{{"[", "{", ""}, {"]", "}", ""}}]
        ], 4],
      Map[
       PasteButton[
         RawBoxes[#]] &, {{UnderscriptBox["\[SelectionPlaceholder]", 
          "︸"], UnderscriptBox["\[SelectionPlaceholder]", "︶"], 
         UnderscriptBox["\[SelectionPlaceholder]", "\[UnderBracket]"],
          UnderscriptBox["\[SelectionPlaceholder]", "_"]},
        {OverscriptBox["\[SelectionPlaceholder]", "︷"], 
         OverscriptBox["\[SelectionPlaceholder]", "︵"], 
         OverscriptBox["\[SelectionPlaceholder]", "\[OverBracket]"], 
         OverscriptBox["\[SelectionPlaceholder]", "_"]}}, {2}]
      ]
     , Spacings -> {0, 0}], FontSize -> 8]
   }]
 ]

All of these templates show some combination of delimiters that can be extended, either vertically or horizontally. To use the vertical unbalanced delimiters, you should normally first make sure that you're in a TraditionalForm environment so that the parser doesn't try to balance the brackets. This is based on my interpretation that you want to use these braces purely in typesetting and not as a function such as Piecewise.

As for the vertical alignment, a palette can also help with that. Have a look at the plain Row and Column templates in the Basic Math Assistant palette, for example.

Usage examples

Typesetting vertically stretched delimiters would realistically happen mostly in a DisplayFormula environment. This is what you see here (numbered equations):

To get these forms, just press the corresponding template button in the palette and then enter the column into the black square indicating the placeholder. Alternatively, highlight an existing column and press the button to apply the delimiters.

Likewise, you can do these things in a text cell by opening an inline cell as one always does for equations, and then proceeding as above:

Answer 4

There are probably easier ways to do this, but nothing comes to mind at the moment:

CellPrint@
  Cell[
   BoxData[
    FormBox[
      GridBox[
      {
       {"\[Piecewise]", 
        GridBox[
         {
          {RowBox[{"x", "\[AlignmentMarker]=", "1", "+", "t"}]},
          {RowBox[{"y", "\[AlignmentMarker]=", "1", "-", SuperscriptBox["t", "2"]}]}
          },
         GridBoxAlignment -> {"Columns" -> {{"\[AlignmentMarker]"}}},
         GridBoxSpacings -> {"Rows" -> {Offset[0.2], {Offset[0.84]}, Offset[0.2]}}]
        }
       }, 
      GridBoxSpacings -> {"Rows" -> {Offset[0.2], {Offset[0.4]}, Offset[0.2]}}], 
      TraditionalForm
     ]
    ], "Output"
  ]
]

Note that the alignment marker will become invisible once you have typed it. See also ref:Structural Elements And Keyboard Characters.

Answer 5

I have used Grid and the Piecewise symbol as follows:

TraditionalForm@
Grid[{{"Parametric equations = ", 
    Style[TraditionalForm@"\[Piecewise]", 
    FontSize -> 36], TraditionalForm[x == 1 + t], 
    0 < t < 1}, {SpanFromAbove, 
    SpanFromAbove, TraditionalForm[y == 1 + t^2], t >= 0}}, 
    Alignment -> {{Center, Center, Left, Center}, Center}]

which gives the following result:

Ideally I'd improve this in the following ways:

1. Find a way to make the bracket less bold.
2. Find a way to make the Grid's Alignment option align on the = character. For some reason this does not behave as I would expect. have