Solve can't solve simple equation

Question

I am having trouble with Mathematicas Solve function. A simple example like this cannot be solved (it basically evaluates the cell forever):

Solve[(x-b)==c (x-b)^(1/a),x]

However, this expression can be readily evaluated by Mathematica:

Solve[(x)==c (x)^(1/a),x]

Once I give extra conditions to the Solve function, it throws an error message that "This system cannot be solved with the methods available to Solve.". For example this one:

Solve[(x-b)==c (x-b)^(1/a) && x!=b,x]

Trying Reduce basically also evaluates the expressions forever. I know I could just solve it by hand, but I'd like to write a bit of automated code for solving certain problems. Is there any way to tell Mathematica that this is indeed solvable? Many thanks!

Answer 1

As often happens, if you help out a bit, your equations can be solved. Recognizing that problems involving powers can often be solved using Logs, try:

Solve[ApplySides[Log, (x - b) == c (x - b)^(1/a)], x]
{x -> b + c^(a/(-1 + a))}

which is the answer you might expect if all the variables had suitable (real and positive) values.

Answer 2

This is not a simple equation. By default, x, a, b, c are treated as complexes and (x - b)^(1/a) is a many-valued (infinitely-valued for some values of the parameters ) expression. Even over the reals, three parameters are too much.

The following work:

Reduce[(y) == c y^(1/a), y, Reals]

(a > 0 && y == 0) || (1/2 (1 - (-1 + a)/a) [Element] Integers && c < 0 && ((a < 0 && y == -(-c)^((a/(-1 + a)))) || (0 < a < 1 && y == -(-c)^((a/(-1 + a)))) || (a > 1 && y == -(-c)^((a/(-1 + a)))))) || (a == 1 && c == 1 && y < 0) || (-((-1 + a)/(2 a)) [Element] Integers && ((a < 0 && c > 0 && y == -c^((a/(-1 + a)))) || (0 < a < 1 && c > 0 && y == -c^((a/(-1 + a)))) || (a > 1 && c > 0 && y == -c^((a/(-1 + a)))))) || (a == 1 && c == 1 && y > 0) || (a < 0 && c > 0 && y == (1/c)^(-(a/(-1 + a)))) || (0 < a < 1 && c > 0 && y == (1/c)^(-(a/(-1 + a)))) || (a > 1 && c > 0 && y == (1/c)^(-(a/(-1 + a))))

and

Solve[(y) == c y^(1/a), y, Reals]

{{y -> ConditionalExpression[0, a > 0]}, {y -> ConditionalExpression[(1/c)^(-( a/(-1 + a))), (0 < a < 1 && c > 0) || (a > 1 && c > 0) || (a < 0 && c > 0)]}, {y -> ConditionalExpression[-(-c)^(( a/(-1 + a))), (1/2 (1 - (-1 + a)/a) [Element] Integers && 0 < a < 1 && c < 0) || (1/2 (1 - (-1 + a)/a) [Element] Integers && a > 1 && c < 0) || (1/2 (1 - (-1 + a)/a) [Element] Integers && a < 0 && c < 0)]}, {y -> ConditionalExpression[-c^(( a/(-1 + a))), (-((-1 + a)/(2 a)) [Element] Integers && 0 < a < 1 && c > 0) || (-((-1 + a)/(2 a)) [Element] Integers && a > 1 && c > 0) || (-((-1 + a)/(2 a)) [Element] Integers && a < 0 && c > 0)]}}

Addition. The command

Solve[(y) == c y^(1/a), y]

performs

{{y -> c^(1/(1 - 1/a))}}

and an error communication "Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information ", but

Reduce[(y) == c y^(1/a), y]

is spinning.

Answer 3

Another way, change variables first.

eq = x - b == c (x - b)^(1/a) /. x - b -> xb
{*  xb == c xb^(1/a)  *}

Solve[eq, xb] // Flatten // Simplify;

xb = xb /. %
{*  c^(a/(a - 1))  *}

Solve[xb == x - b, x]
(*  {x -> c^(a/(a - 1)) + b}  *}

Of course we are making assumptions about x-b being positive and a-1!=0 which I am surprised that Mathematica did not point out as picky as version 13 is about Solve.