5
$\begingroup$

I would really appreciate it if someone would be able to help me generate the following figure in Mathematica.

image to be replicated

This is what I have started with:

redius = 6;
center = 3;
font = 15;

Graphics[{
  Circle[{-center, -center}, redius], 
  Circle[{-center, center}, redius], 
  Circle[{center, -center}, redius], 
  Circle[{center, center}, redius],
  Black, Text[Style["Technical Tools", FontSize -> font], {-redius, center + 2}],
  Black, Text[Style["Human \n Aspect", FontSize -> font], {center + 1, redius + 1}],
  Black, Text[Style["Mental \n Process", FontSize -> font], {-redius, -redius + 1}], ,
  Black, Text[Style["Paperwork \n Process", FontSize -> font], {redius, -center - 1}]
}]

and I have been able to generate the following figure.

my best attempt

$\endgroup$
3
  • $\begingroup$ What have you tried? $\endgroup$
    – C. E.
    Commented Nov 12, 2019 at 19:42
  • 3
    $\begingroup$ With[{a = 0.5, r = 1}, Graphics[{ EdgeForm[ Black], {Opacity[0.2, #[[1]]], Disk[#[[2]], r], {Opacity[1, Black], Text[Style[#[[3]], Bold], 1.75 #[[2]]]}} & /@ {{Red, {-a, a}, "Technical\nTools"}, {Blue, {a, a}, "Human\nAspect"}, {Orange, {a, -a}, "Mental\nProcess"}, {Green, {-a, -a}, "Paperwork\nProcess"}}, Opacity[1, Black], Text[Style["Education", Bold], {0, 0}]}]] $\endgroup$
    – Bob Hanlon
    Commented Nov 12, 2019 at 20:47
  • $\begingroup$ @ Bob, your comment is more than an answer. Thank you. $\endgroup$
    – DLT
    Commented Nov 13, 2019 at 1:05

2 Answers 2

13
$\begingroup$
SeedRandom[1234]
colors = RandomColor[4];
centers = Tuples[{-1, 1}/2, {2}];

Graphics[MapThread[{Opacity[.5], #, EdgeForm[{Darker@#, Thick}], Translate[Disk[], #2]} &, 
   {colors, centers}]]

enter image description here

colors = {Red, Green, Blue, Yellow};
labels = {"Paperwork Process", "MentalProcess", "Human Aspect", "Technical Tools"};


Graphics[{MapThread[{EdgeForm[{Darker@#, Thick}], #, Translate[Disk[], #2], 
  Text[Style[#3, 14, FontOpacity -> 1, FontColor -> Black], {4, 3} #2], 
  Arrowheads[Medium], Black, Arrow[{{4, 2.75} #2, {3, 2} #2}]} &, 
  {colors, centers, labels}], 
 Opacity[1], Text[Style["Education", 14], {0, 0}]}, 
 ImageSize -> Large]

enter image description here

$\endgroup$
2
  • $\begingroup$ I really appreciate it, kglr. This was what I was looking for. Thank you so much $\endgroup$
    – DLT
    Commented Nov 13, 2019 at 5:30
  • $\begingroup$ @DLT, my pleasure. Thank you for the accept. $\endgroup$
    – kglr
    Commented Nov 13, 2019 at 5:32
5
$\begingroup$

The midpoints of the four circles(radius r) lie on a square(sidelength a) Change Circle to Disk to get colored circles.

With[{a = 0.5, r = 1}, Graphics[{ EdgeForm[Black], Opacity[.2],
FaceForm[Blue], Disk[{a, a}, r], Circle[{-a, a}, r],Circle[{-a, -a}, r] , Circle[{ a, -a}, r]}]]

enter image description here

$\endgroup$
2
  • 1
    $\begingroup$ Thank you Ulrich but I also need different colors and texts as well as shown in the figure. $\endgroup$
    – DLT
    Commented Nov 12, 2019 at 20:26
  • $\begingroup$ Change Circle to Disk. FaceForm[color] changes the color. See my edit. $\endgroup$ Commented Nov 12, 2019 at 20:35

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.