Simplify makes Mathematica forget that a matrix is Hermitian

Question

Using Simplify with certain trivial assumptions makes Mathematica forget that a given matrix is Hermitian. See the minimal example below:

expr = Exp[I*2*π*Re[n]]
mat = {{Re[n], a*expr}, {Conjugate[a]*Conjugate[expr], Re[n]}}
HermitianMatrixQ[mat]
simplifiedmat = Assuming[n ∈ Integers, Simplify[mat]]
HermitianMatrixQ[simplifiedmat]

Here I create a Hermitian matrix mat with some integer variable n. Mathematica correctly asserts that mat is Hermitian. After this I simplify the matrix under the assumption that n is an integer. This nicely removes the exponential expression in the matrix, as expected. However, according to Mathematica this simplified matrix simplifiedmat is no longer Hermitian.

This is clearly wrong. Thus I ask if there is any other way to simplify mat and maintaining that simplifiedmat is Hermitian?

Answer 1

There are two issues here. The first is that HermitianMatrixQ (in line with other Q functions) only applies quick checks that the matrix is Hermitian. It is acceptable for it to fail to recognise a matrix as Hermitian, but it must not say that a matrix is Hermitian when it is not.

Secondly, when you apply the test, your assumption for n is no longer active. HermitianMatrixQ has to assume it is complex.

Note further (I think) in general Q functions do not take account of assumptions. We have

Assuming[n ∈ Integers, HermitianMatrixQ[simplifiedmat]]
(* False *)

Answer 2

expr = Exp[I*2*π*Re[n]];
mat = {{Re[n], a*expr}, {Conjugate[a]*Conjugate[expr], Re[n]}};
HermitianMatrixQ[mat]

(* True *)

simplifiedmat = Assuming[n ∈ Integers, Simplify[mat]];

Use the SameTest option to HermitianMatrixQ to make use of Assumptions

HermitianMatrixQ[simplifiedmat, 
 SameTest -> (Simplify[#1 - #2 == 0, Element[n, Integers]] &)]

(* True *)

Answer 3

The essential problem is that simplifiedmat is

{{n, a}, {Conjugate[a], n}}

Note that this expression contains no hint about the nature of n. You told Simplify that n was an integer, so it naturally simplified Re[n] to n. One way to fix this is to restore the Re after simplifying:

HermitianMatrixQ[simplifiedmat /. n -> Re[n]]
(* True *)

Answer 4

From the answers above I learned that, unlike sympy, Mathematica does not keep track of assumptions and some functions simply ignore assumptions even if given explicitly.

Thus I thought some more about how to make a symbol n∈ℝ in the first place and that's surprisingly simple. Just define n as the real part of some new and otherwise unused symbol nComplex: n = Re[nComplex]. The whole code then becomes

n = Re[nComplex]
expr = Exp[I*2*π*Re[n]]
mat = {{Re[n], a*expr}, {Conjugate[a]*Conjugate[expr], Re[n]}}
HermitianMatrixQ[mat]
simplifiedmat = Assuming[n ∈ Integers, Simplify[mat]]
HermitianMatrixQ[simplifiedmat]

I have to admit that outputting matrices mat and simplifiedmat now looks rather ugly, but it does the job without me having to keep track of and reinserting all assumptions after every time I run Simplify.