How can I always get one option of coordinates of the points A, B, C, D, and X of the Problem 6 in IMO 2018?

Question

This is the Problem 6 of IMO 2018 https://www.imo-official.org/problems.aspx

I use the code at Mapleprimes (with some prepairs) https://www.mapleprimes.com/questions/228162-How-Can-I-Get-One-Option-Coordinates

a = {0, 0};
b = {5, 0};
c = {3, 4};
d = {15 - 4*Sqrt[19], 6};
x = {-172*Sqrt[19]*(1/757) + 1839/757, 2762/757 - 176*Sqrt[19]*(1/757)};

I checked the conditions and all of them are true.

EuclideanDistance[a, b] * EuclideanDistance[c, d] - 
  EuclideanDistance[a, d] * EuclideanDistance[c, b] // Simplify

VectorAngle[a - x, a - b] - VectorAngle[c - x, c - d] // Simplify

VectorAngle[b - x, b - c] - VectorAngle[d - x, d - a] // FullSimplify

But, when I change coordinates one point A, B, C, then sometimes, I can not get the result.

How can I always get one option of coordinates of the points A, B, C, D, and X of the Problem 6 in IMO 2018?

Answer 1

Use RandomInstance and GeometricScene:

ri = RandomInstance[
    GeometricScene[{a, b, c, d, x},
        {
            p1 == Polygon[{a, b, c, d}],
            Equal[EuclideanDistance[a, b] * EuclideanDistance[c, d],
                    EuclideanDistance[b, c] * EuclideanDistance[d, a]
                ],
            GeometricAssertion[p1, "Convex"],
            x \[Element] p1,
            PlanarAngle[{x, a, b}] == PlanarAngle[{x, c, d}],
            PlanarAngle[{x, b, c}] == PlanarAngle[{x, d, a}]
        }
    ]
 ]

Extract the point coordinates:

points = ri["Points"]

Confirm that the conclusion holds:

(PlanarAngle[{b, x, a}] + PlanarAngle[{d, x, c}])/Degree /. points