Update 2 Express Energy Balance in Coefficient Form
The most direct way to introduce $\kappa$ is to express the energy (not temperature) balance in coefficient form as described here and shown below.
$$m\frac{{{\partial ^2}}}{{\partial {t^2}}}u + d\frac{\partial }{{\partial t}}u + \nabla \cdot\left( { - c\nabla u - \alpha u + \gamma } \right) + \beta \cdot\nabla u + au - f = 0$$
In this case, only the $d$ and $c$ term are non-zero and given by:
$$d = \rho {{\hat C}_p} = \frac{\kappa }{D}$$
$$c=\kappa$$
This time, we will make the second phase a dense insulating material.
L1 = -1;
L2 = 1;
D1 = 1;
D2 = 1/160;
k1 = 1;
k2 = 0.1;
rhocp1 = k1/D1;
rhocp2 = k2/D2;
Temp = 0;
nv = NeumannValue[Cos[ Pi t], x == L1];
dc = DirichletCondition[u[t, x] == Temp, x == L2];
ic = u[0, x] == Temp;
pde = If[x < 0, rhocp1, rhocp2] D[u[t, x], t] +
D[-If[x < 0, k1, k2] D[u[t, x], x], x] == nv;
uif = NDSolveValue[{pde, dc, ic}, u, {t, 0, 10}, {x, L1, L2}];
imgs = Table[
Plot[uif[t, x], {x, L1, L2}, PlotRange -> {-0.55, 0.55},
ImageSize -> Medium], {t, 0, 10, 0.1}];
ListAnimate@imgs
Expressing PDEs in coefficient form make it easier to map to other solvers.
Again, Mathematica compares favorably to another solver giving me more confidence in the approach.
Update 1 To Perform Balance on Energy Instead of Temperature
If one wants to use a single state variable for thermal problems with distinct phases, then one should use enthalpy change instead of temperature as the field variable. The conservation equation in terms of enthalpy change becomes:
$$\frac{\partial }{{\partial t}}\rho {{\hat C}_p}T + \nabla \cdot \left( { - \alpha \nabla \rho {{\hat C}_p}T} \right) = 0$$
It is natural to set the field variable, $u$, to
$$u = \rho {{\hat C}_p}(T - {T_0})$$
Leading to a single pde for energy
$$\frac{\partial }{{\partial t}}u + \nabla \cdot \left( { - \alpha \nabla u} \right) = 0$$
This was the PDE that was solved previously. One has to think carefully about how to preserve temperature continuity. We should be able to convert back to temperature as a post-processing step by defining a piecewise function like:
$$T(t,x) = {T_0} + \frac{{u(t,x) - u(0,x)}}{{{\rho _1}{{\hat C}_{p1}}}};x < 0$$
$$T(t,x) = {T_0} + \frac{{u(t,0) - u(0,0)}}{{{\rho _1}{{\hat C}_{p1}}}} + \frac{{u(t,x) - u(t,0)}}{{{\rho _2}{{\hat C}_{p2}}}};Otherwise$$
At $x=0$, temperature continuity is preserved.
Comparison to Another Code
When possible, it is conducive to compare results among different codes. Here, I compare the Mathematica result to the Heat Transfer in Solids module in COMSOL where $\rho {{\hat C}_p}$ is held constant. The results look qualitatively similar.
Mathematica
imgs = Table[
Plot[uif[t, x], {x, L1, L2}, PlotRange -> {-0.5, 0.5},
ImageSize -> Medium], {t, 0, 10, 0.1}];
ListAnimate@imgs
COMSOL
Previous Answer
As stated in the comments, you only need one field variable and a spatially diffusion coefficient. Since you did not provide parameter values, I created a case with test values.
L1 = -1;
L2 = 1;
D1 = 1;
D2 = 0.1;
Temp = 0;
nv = NeumannValue[Cos[ Pi t], x == L1];
dc = DirichletCondition[u[t, x] == Temp, x == L2];
ic = u[0, x] == Temp;
pde = D[u[t, x], t] + D[-If[x < 0, D1, D2] D[u[t, x], x], x] == nv;
uif = NDSolveValue[{pde, dc, ic}, u, {t, 0, 10}, {x, L1, L2}];
Plot3D[uif[t, x], {x, L1, L2}, {t, 0, 10}, PlotPoints -> 50,
PlotRange -> All]
