0
$\begingroup$

I'm Trying to solve dynamical system in friedmann universe. But, I have problems with initial conditions to $\Omega_{\Lambda}$ and $\Omega_{k}$. The code that i'm implementing is

ode1[x0_, y0_] := NDSolve[{x'[n]] == 2 (1 + (3 \[Gamma] - 2)/2 (1 - y[n]) - (3 \[Gamma])/2 x[n]) x[n],  y'[n] ==  2 ((3 \[Gamma] - 2)/2 (1 - y[n]) - (3 \[Gamma])/ 2 x[n]) y[n], x0] == x0, y[0] == y0}, {x[n], y[n]}, {n, -0.7, 0.54}, MaxSteps -> Infinity]

Where $\gamma=1$, $n=\ln a$, $x=\Omega_{\Lambda}$ and .$y=\Omega_{k}$ For example, I try

sol[1] = ode1[-0.5, 1.5]; sol[2] = ode1[1, 0]; sol[3] = ode1[0, 1]; sol[4] = ode1[0.8, 0.2]; sol[5] = ode1[-0.3, 1.3]; sol[6] = ode1[1.3,-0.3]; sol[7] = ode1[1.2, -0.2]; sol[8] = ode1[0.2, 0.8];

ParametricPlot[Evaluate[Table[{x[n], y[n]} /. sol[i], {i,8}]], {n, -0.7, 0.54}, PlotStyle -> {Thick}, PlotRange -> {{-0.5, 1.5}, {-0.5, 1}}, PlotPoints -> 100, AxesLabel -> {"x", "y"}, Axes -> True]

The plot shows anything.

$\endgroup$
3
$\begingroup$

Use code

ode1[x0_, y0_] := 
 NDSolve[{x'[n] == 
     2 (1 + (3 \[Gamma] - 2)/2 (1 - y[n]) - (3 \[Gamma])/2 x[n]) x[n],
     y'[n] == 
     2 ((3 \[Gamma] - 2)/2 (1 - y[n]) - (3 \[Gamma])/2 x[n]) y[n], 
    x[0] == x0, y[0] == y0} /. \[Gamma] -> 1, {x, y}, {n, -0.7, 0.54},
   MaxSteps -> Infinity]
sol[1] = ode1[-0.5, 1.5]; sol[2] = ode1[1, 0]; sol[3] = ode1[0, 1]; 
sol[4] = ode1[0.8, 0.2]; sol[5] = ode1[-0.3, 1.3]; 
sol[6] = ode1[1.3, -0.3]; sol[7] = ode1[1.2, -0.2]; 
sol[8] = ode1[0.2, 0.8];

ParametricPlot[
 Evaluate[Table[{x[n], y[n]} /. sol[i], {i, 8}]], {n, -0.7, 0.54}, 
 PlotStyle -> {Thick}, PlotRange -> All, PlotPoints -> 100, 
 AxesLabel -> {"x", "y"}, Axes -> True]

Figure 1

Phase space of the system

reg = ImplicitRegion[
  1 - x - y < 0 && -.5 <= x <= 1.5 && -1 <= y <= 1, {x, y}]; reg1 = 
 ImplicitRegion[
  1 - x - y > 0 && -.5 <= x <= 1.5 && -1 <= y <= 1, {x, y}];

sp = StreamPlot[{2 (1 + (3 \[Gamma] - 2)/2 (1 - y[n]) - (3 \[Gamma])/
         2 x[n]) x[n], 
    2 ((3 \[Gamma] - 2)/2 (1 - y[n]) - (3 \[Gamma])/2 x[n]) y[
      n]} /. \[Gamma] -> 1, {x[n], y[n]} \[Element] reg1, 
  FrameLabel -> {Subscript[\[CapitalOmega], \[CapitalLambda]], 
    Subscript[\[CapitalOmega], K]}, StreamPoints -> Fine]

rp = Show[RegionPlot[reg, BoundaryStyle -> None], 
  Graphics[{Black, Circle[{0, 0}, 2], 
    Inset[\[CapitalOmega] < 0, {1, 0.5}]}]]
Show[sp, rp]

sp1 = StreamPlot[{2 (1 + (3 \[Gamma] - 2)/2 (1 - y[n]) - (3 \[Gamma])/
         2 x[n]) x[n], 1 - x[n] - y[n]} /. \[Gamma] -> 1, {x[n], -.5, 
   1.5}, {y[n], 0., 2}, 
  FrameLabel -> {Subscript[\[CapitalOmega], \[CapitalLambda]], \
\[CapitalOmega]}, StreamPoints -> Fine]

Figure2

$\endgroup$
  • $\begingroup$ Thanks for your answer, the problem is that I want to reproduce the figure 2 [link] (arxiv.org/abs/physics/0108066v1) in page 13. $\endgroup$ – Fisjog Oct 24 '19 at 20:18
  • $\begingroup$ @Fisjog Show how to do it? $\endgroup$ – Alex Trounev Oct 24 '19 at 21:11
  • $\begingroup$ thanks a lot! @alex-trounev $\endgroup$ – Fisjog Oct 24 '19 at 22:34

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.