0
$\begingroup$

I want to solve these equations for "r" and \theta. But, mathematica is unable to produce output. Can anyone help me please to find the values for "r" and \theta? Here, "k" can be fixed by 0.75.

1/r^4 2 (r^2 + (L - B r^k + 
            B r^k Cos[\[Theta]])^2 Csc[\[Theta]]^2 - (-2 + r) (L - B r^k +
             B r^k Cos[\[Theta]]) (L + B (-1 + k) r^k - 
            B (-1 + k) r^k Cos[\[Theta]]) Csc[\[Theta]]^2) == 0
    ((-2 + r) (L - B r^k + 
        B r^k Cos[\[Theta]]) (B r^
         k + (L - B r^k) Cos[\[Theta]]) Csc[\[Theta]])/r == 0
$\endgroup$
5
  • $\begingroup$ I deleted my answer as in the OP it said k equal zero and the solution was wrong. $\endgroup$ – DiSp0sablE_H3r0 Oct 17 '19 at 13:44
  • $\begingroup$ What are the constraints on L and B? Is r strictly positive? non-negative? Does theta have a restricted range? $\endgroup$ – KennyColnago Oct 17 '19 at 15:47
  • $\begingroup$ Both your equations are numerators/r==0. Using Limit to check for r->-Infinity, r->0 and r->Infinity shows none of those are solutions. Thus I believe you can discard your denominators and solve for numerators==0 which should be slightly easier. $\endgroup$ – Bill Oct 17 '19 at 17:27
  • $\begingroup$ Dear KennyColnago, L is a positive number, B can be both positive and negative, r should be positive. No, \theta has no restricted range. $\endgroup$ – MMS Oct 17 '19 at 18:47
  • $\begingroup$ Dear KennyColnage, can you help me please in solving the above mentioned equations? I have tried a lot using different ways but not getting answer. $\endgroup$ – MMS Oct 19 '19 at 20:47
2
$\begingroup$

Since you fix k value to 0.75 and not to 3/4 I guess you want numerical solution, which can be obtained after values for all other symbols (except [Theta] and r) are fixed. If you really want some symbolical expression (for k=3/4 case), then you can try to attack the problem in the way sketched below. It is not the answer

Of course, your cannot hope for nice solutions. Also your will definitely obtain parasite solutions. Also solutions most probably will not be valid for all parameter B, L, etc values. So you always need to check them numerically, etc... Also, I never attempted to verify this method for exponential and non-exponential type of variables, though it worked fine, say for two angle, say, theta and phi variables.

First of all I will use trick which replaces exponents to polynomials.

eqs = FullSimplify[(Thread[
 Equal[Last /@ (Numerator /@ (First /@ (Together /@ 
         Replace[
          Expand[TrigToExp[{1/
                r^4 2 (r^2 + (L - B r^k + 
                B r^k Cos[\[Theta]])^2 Csc[\[Theta]]^2 - (-2 + 
                r) (L - B r^k + B r^k Cos[\[Theta]]) (L + 
                B (-1 + k) r^k - 
                B (-1 + k) r^k Cos[\[Theta]]) Csc[\[Theta]]^2) == 
              0,
             ((-2 + r) (L - B r^k + 
                B r^k Cos[\[Theta]]) (B r^
                k + (L - B r^k) Cos[\[Theta]]) Csc[\[Theta]])/r ==
               0}]], Power[E, 
            Times[Complex[0, n_Integer], x_Symbol]] :> x^n, 
          All]))), {0, 0}]] /. k -> 3/4)]

out1:

{B^2 (-6 + r) r^(3/2) (-1 + \[Theta])^4 + 
   2 B L r^(3/4) (-18 + 5 r) (-1 + \[Theta])^2 \[Theta] + 
   4 (r^2 - 2 (-2 L^2 (-3 + r) + r^2) \[Theta]^2 + r^2 \[Theta]^4) == 
  0, (-2 + r) (B r^(3/4) (-1 + \[Theta])^2 + 
     2 L \[Theta]) (B r^(3/4) (-1 + \[Theta])^2 - 
     L (1 + \[Theta]^2)) == 0}

Now we have polynomial type (in fact which can be turned into polynomials) equations, and it is very important that the last equation factorizes (we hoped for this since the initial equation had this property). Now we can Eliminate (or even better approach would be to compute GroebnerBasis) with the first equation and each factor of the second equation.

Something like

eq4r=Eliminate[{B^2 (-6 + r) r^(3/2) (-1 + \[Theta])^4 + 
    2 B L r^(3/4) (-18 + 5 r) (-1 + \[Theta])^2 \[Theta] + 
    4 (r^2 - 2 (-2 L^2 (-3 + r) + r^2) \[Theta]^2 + r^2 \[Theta]^4) ==
    0, (B r^(3/4) (-1 + \[Theta])^2 + 2 L \[Theta]) == 0}, \[Theta]]

out2:

-L^5 r^2 + 16 B^4 L r^5 == 0

Which is solvable with Solve. Unfortunately the third factor still causes problems (I had no time to wait for result), which means, that not all solutions are found.

Now you should do back substitutions to get Theta (do not forget to turn them into exponents) and carefully check (numerically, of course) for parasite and invalid solutions and hope that the missed solution (of the third factor) is not the physical solution your are interesting in.

So, do your still need symbolic solution? Next step (extension under request)

sol1r = Solve[eq4r, r];
sol1r[[3]]

out3:

{r -> -(((-(1/2))^(1/3) L^(4/3))/(2 B^(4/3)))}

Substitute it to your first equation:

eq4q = (Numerator[
    Together[
     Expand[TrigToExp[((1/
             r^4 2 (r^2 + (L - B r^k + 
                  B r^k Cos[\[Theta]])^2 Csc[\[Theta]]^2 - (-2 + 
                 r) (L - B r^k + B r^k Cos[\[Theta]]) (L + 
                 B (-1 + k) r^k - 
                 B (-1 + k) r^k Cos[\[Theta]]) Csc[\[Theta]]^2)) /. 
          k -> 3/4) /. sol1r[[3]]]]]] == 0)

out4: (* large expression *)

Then

Solve[eq4q, \[Theta]]

yields very large symbolic answer. You have to do it for every root of sol1r. Still this will be only partial solution using the second factor of your equation. It can happen that it will be nonphysical or even parasite (i.e. not solution at all). You have always to check them numerically. That is you have to substitute numerical (preferably rational) numbers for all parameters of your equations and solve them numerically (with FindRoot[ ] using different starting values, for example). Then substitute the same numerical values to your symbolic answer and hope that one of them will match the numerical answer (there should be a number of them). So, time eating and hard work with little hope for success.

$\endgroup$
3
  • $\begingroup$ Thanks, means we can find "r" using Sove from Out2, but how can we find \theta? and how can we do back substitution? means back into exponents. $\endgroup$ – MMS Oct 19 '19 at 19:52
  • $\begingroup$ The second equation of your systems is a factor of three terms. The out2 demonstrates that something nontrivial can possibly obtained using the second factor. So your solve for r: sol1r = Solve[out2, r]; Then take one of solutions, say sol1r[[3]] substitute it into the first of your equations and solve. I extended the answer. $\endgroup$ – user18792 Oct 21 '19 at 6:59
  • $\begingroup$ Thank you so much for such a nice explanation and kind help. $\endgroup$ – MMS Oct 21 '19 at 12:19

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.