1
$\begingroup$

This works:

n = Infinity;
Region[ParametricRegion[{1 - (b1 (1 + b2))/(1 + b1^2 + b2^2), 
   1 - 2 ArcSin[
      1/2 Sqrt[(1 + b1^2 + (-1 + b2) b2)/(
       1 + b1^2 + b2^2 - b1 (1 + b2))]]/π}, {{b1, -n, n}, {b2, -n,
     n}}], Frame -> True, AspectRatio -> 1/GoldenRatio]

enter image description here

but this doesn't:

n = Infinity;
Region[ParametricRegion[{1 - a1 + ((-1 + a1^2) b1)/(
    1 + 2 a1 b1 + b1^2), 
   1 - 2 ArcSin[
      1/2 Sqrt[((1 + a1) (1 + b1 (a1 + b1)))/(
       1 + b1 (-1 + a1 + b1))]]/π}, {{a1, -1, 1}, {b1, -n, n}}], 
 Frame -> True, AspectRatio -> 1/GoldenRatio]

I.e., it runs for too long for me to hope it will give any output. It works for n=1, though. But theory says that $-\infty<b_1<\infty$, and the functions I'm trying to plot are well defined for all $b_1\in\mathbb{R}$. However, the first component is restricted to $[0,1]$, thus the contraints:

Reduce[0 < 1 - a1 + ((-1 + a1^2) b1)/(1 + 2 a1 b1 + b1^2) < 1 && -1 < a1 < 1, {a1, b1}]

(-1 < a1 < 0 && -a1 < b1 < -(1/a1)) || (a1 == 0 && b1 > 0) || (0 < a1 < 1 && (b1 < -(1/a1) || b1 > -a1))

which look like this:

enter image description here

On other hand,

RegionBounds@
 ParametricRegion[{1 - a1 + ((-1 + a1^2) b1)/(1 + 2 a1 b1 + b1^2), 
   1 - 2 ArcSin[
      1/2 Sqrt[((1 + a1) (1 + b1 (a1 + b1)))/(
       1 + b1 (-1 + a1 + b1))]]/π}, {{a1, -1, 1}, {b1, -Infinity, 
    Infinity}}]

gives

{{0, 2}, {1/3, 1}}

What can be done to have it plotted in MMA v11.3?

$\endgroup$
2
$\begingroup$

We can split the domain into multiple finite pieces:

opts = {Mesh -> None, PlotStyle -> {Opacity[1], Hue[0.6, 0.3, 0.95]}, 
  BoundaryStyle -> None, PlotPoints -> 50};

f[a1_, b1_] := {1 - a1 + ((-1 + a1^2) b1)/(1 + 2 a1 b1 + b1^2), 
  1 - 2 ArcSin[1/2 Sqrt[((1 + a1) (1 + b1 (a1 + b1)))/(1 + b1 (-1 + a1 + b1))]]/π}

Show[
  ParametricPlot[f[a1, b1], {a1, -1, 1}, {b1, -1, 1}, Evaluate@opts],
  ParametricPlot[f[a1, 1/b1], {a1, -1, 1}, {b1, 0, 1}, Evaluate@opts],
  ParametricPlot[f[a1, 1/b1], {a1, -1, 1}, {b1, -1, 0}, Evaluate@opts],
  AspectRatio -> 1/GoldenRatio,
  PlotRange -> All
] // Quiet

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.